Como obtener los datos correspondientes a una referencia

tengo una base da datos de la cual tengo que extraer todos los números de parte solicitados  para un caso

por ejemplo

de este caso 702199144 se le asignaron 3 partes, lo que requiero es que si en otra hoja pongo el caso automáticamente me ponga todos los order P/N que tiene ese caso.

saludos y gracias

1

1 respuesta

Respuesta
2

Te anexo una opción con una macro:

Private Sub Worksheet_Change(ByVal Target As Range)
'Por.Dante Amor
    If Target.Count > 1 Then Exit Sub
    If Not Intersect(Target, [B2]) Is Nothing Then
        Set h1 = Sheets("Hoja1")
        Set h2 = Sheets("Hoja2")
        '
        j = 2
        h2.Columns("C").ClearContents
        Set r = h1.Columns("A")
        Set b = r.Find(Target, lookat:=xlWhole)
        If Not b Is Nothing Then
            ncell = b.Address
            Do
                'detalle
                h2.Cells(j, "C") = h1.Cells(b.Row, "C")
                j = j + 1
                Set b = r.FindNext(b)
            Loop While Not b Is Nothing And b.Address <> ncell
        Else
            MsgBox "El número de caso no existe", vbExclamation
        End If
    End If
End Sub

Cambia en la macro "hoja1" por el nombre de tu hoja que tienes los datos;

"Hoja2" por la hoja donde quieres los resultados.


Sigue las Instrucciones para poner la macro en los eventos de worksheet

  1. Abre tu libro de excel
  2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
  3. Del lado izquierdo dice: VBAProject, abajo dale doble click a worksheet(la hoja de resultados)
  4. Del lado derecho copia la macro

Ahora, regresa a tu hoja de resultados y escribe en la celda B2 el número de caso, la macro en automático te pondrá en la columna C todos los Order P/N que encuentre.


Saludos. Dante Amor

Si es lo que necesitas.

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas