¿Cómo puedo controlar unos vídeos en formato avi con botones propios en el Macromedia Director?

Te pongo aquí mi comportamiento de video. Una cosa; te recomiendo que no uses avi y que uses quicktime, porque los controles sobre avi no funcionan bien, debido a que lingo en este tema falla mucho.
Solo tendrás que vincular el comportamiento sobre cualquier miembro para poder elegir la acción (play, stop, rewing...)
Si no eres capaz de usarlo me lo comentas y te echo una mano.
property p_tipo_control, pVideoSprite,ptitulo
on getPropertyDescriptionList me
list = [:]
addProp list, #ptitulo,[#comment:"comportamiento realizado por",#format:#symbol,#range:[#bedelludrica],#default:#bedelludrica]
addProp list, #p_tipo_control, [#comment: "accion de este boton",\
#format: #symbol,¬
#range: [#play, #stop, #pausa, #salto_adelante, #salto_atras,\
#vete_comienzo, #marcha_atras, #adelante_rapido, #atras_rapido, #vete_final, #repeticion],\
#default: #stop]
addProp list, #pVideoSprite, [#comment: "¿cual es el sprite de video?",\
#format: #sprite, #default: 1]
return list
end
on mouseUp me
case p_tipo_control of
#play:
sprite(pVideoSprite).movieRate = 1
#stop:
sprite(pVideoSprite).movieRate = 0
sprite(pVideoSprite).movieTime = 0
#vete_comienzo:
sprite(pVideoSprite).movieRate = 0
sprite(pVideoSprite).movieTime = 0
#vete_final:
sprite(pVideoSprite).movieRate = 0
sprite(pVideoSprite).movieTime = sprite(pVideoSprite).duration
#marcha_atras:
sprite(pVideoSprite).movieRate = -1
#pausa:
sprite(pVideoSprite).movieRate = 0
#salto_adelante:
sprite(pVideoSprite).movieTime = sprite(pVideoSprite).movieTime + 4*60
#salto_atras:
sprite(pVideoSprite).movieTime = sprite(pVideoSprite).movieTime - 4*60
#adelante_rapido:
sprite(pVideoSprite).movieRate = 3
#atras_rapido:
sprite(pVideoSprite).movieRate = -3
#repeticion:
sprite(pVideoSprite).member.loop = ¬
not sprite(pVideoSprite).member.loop
end case
end

Hiola Belle gracias por tu comportamiento, pero tengo un problema he copiado tu código tal y como lo pusiste no me da error de script pero no me controla el video.
La verdad es que no comprendo el código y por eso no me aclaro mucho, si me`puedes explicar como funciona el código, que hace cada elemento y donde tengo que colocar este behaviour tal vez me aclare un poco más.
Muchas gracias por todo Belle y espero no ser muy palizas pero la verdad es que estoy empezando con director y el lingo se me resiste mucho.

Me imagino que es porque no lo has convertido en comportamiento.
Para ello desde la ventana script debes pulsar sobre el botón azul con la letra "i" que se encuentra en la parte superior.
Se te ha abierto una ventana donde debes poner la opción movie a behaviour.
Una vez echo esto, ya tienes un comportamiento listo para ser usado.
Para usarlo debes abrir la ventana del cast.
Suponiendo que ya tienes todos los botones que quieres usar en el stage y el video también...
Solo te queda arrastrar el comportamiento desde el stage hasta todos los botones para hacerlos funcionar.
Cuando arrastres el comportamiento se te abrirá una ventana donde debes indicar la acción que realizara ese botón y el sprite donde se encuentra el video.
Es igual que los comportamientos que encuentras en la library palette del menu window.
Si no era esta la duda me lo dices.