Envío de mail desde excel, pero con mail laboral ( plataforma Gmail)

H   o la:

La única macro que tengo para enviar correos desde Gmail es esta:

Sub EnviarGmail()
'Por.Dante Amor
    correo = "[email protected]"
    passwd = "pwd"
    '
    Application.DisplayAlerts = False
    Application.ScreenUpdating = False
    '
    Dim Email As CDO.Message
    Set Email = New CDO.Message
    Email.Configuration.Fields(cdoSMTPServer) = "smtp.gmail.com"
    Email.Configuration.Fields(cdoSendUsingMethod) = 2
    With Email.Configuration.Fields
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = CLng(465)
        .Item("http://schemas.microsoft.com/cdo/" & "configuration/smtpauthenticate") = Abs(1)
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 30
        .Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = correo
        .Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = passwd
        .Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = True
    End With
    With Email
        .To = "[email protected]"
        .From = correo
        .Subject = "Asunto del correo"
        '.TextBody = "Cuerpo del coreo"
        '.AddAttachment ruta & nombre & ".xlsx"
        .Configuration.Fields.Update
        On Error Resume Next
        .Send
    End With
    If Err.Number = 0 Then
        MsgBox "El mail se envió con éxito"
    Else
        MsgBox "Se produjo el siguiente error: " & Err.Number & " " & Err.Description
    End If
    Set Email = Nothing
End Sub

Para probar la macro, cambia en esta línea [email protected] por tu correo de gmail

correo = "[email protected]"

En esta línea pwd por tu password

passwd = "pwd"

Y en esta línea [email protected] por algún correo para enviar la prueba 

To = "[email protected]"

Sigue las Instrucciones para ejecutar la macro

1. Abre tu archivo de excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. En el menú elige Insertar / Módulo
4. En el panel del lado derecho copia la macro
5. Para ejecutarla presiona F5

También entra a VBA, en el menú Herramientas / Referencias, busca la que dice Microsoft CDO for Windows 2000 Library, y marca la casilla.

Otra cosa más, en la configuración del mail de Gmail tienes que entrar a "Aplicaciones menos seguras"

https://www.google.com/settings/security/lesssecureapps 

Y seleccionar la opción "Activar"

De esa forma podrás enviar correos desde otra aplicación.

Realiza la prueba. Si te funciona, entonces revisamos exactamente qué es lo que vas a enviar.

Sal u dos