Buscar valor más cercano cumpliendo 2 condiciones

Respuesta de
a
Usuario
Hola Expertos, gracias de antemano por leerme, espero puedan guiarme en mi problema, aún no he conseguido amarrarlo del todo. El problema es el siguiente: Tengo un listado en la columna A1:A21 con 7 tipos de referencias (3 de cada una), y en la B1:B21 aparecen sus importes. Por otro lado tengo un listado con las mismas referencias pero con importes en ocasiones iguales y otras con pequeñas diferencias. Ejemplo con solo 2 referencias:

       A B C D

1   101      $15.90         101         $15.80

2   101      $10.15         101          $10.15

3    101      $ 13.50        101         $13.70

4    102      $15.90          102         $15.80

5     102       $11.70          102          $10.30

6     102       $9.85            102         $10.15

 

Estoy tomando como referencia mi cuadro C y D y que me arroje el valor más cercano de B en cada fila, cumpliendo la condición de A con C (que sea la misma referencia). La fórmula que tengo es la siguiente, pero le falla por que busca que la cantidad sea exacta. Recuerden que es formula matricial ctrl+mayus+enter

=INDICE(B1:B6,COINCIDIR(C1&D1,A1:A6&B1:B6,0))   

Esta fórmula me arroja, los valores que coinciden exactamente como la segunda fila, cuando no coinciden me arroja error y deseo que me arroje el resultado más cercano, pero que coincida la referencia.

Otra fórmula que tengo es:

=+INDICE(B1:B6,COINCIDIR(K.ESIMO.MENOR(ABS(D1-B1:B6),1),ABS(D1-B1:B6),0))

Aquí me arroja los importes más cercanos, pero sin importar la referencia.

Busco la integración de ambas fórmulas, para que así puede darme como resultado el importe más cercano (mayor o menor) pero que sea de la misma referencia. En la columna E, tendría que arrojarme como resultado en la fila 1 $15.90, en la 2 $10.15 y así sucesivamente.

Muchas gracias Expertos y les agradezco el apoyo.

Saludos

 
Avatar
Experto
Prueba con

=INDICE($B$1:$B$6,COINCIDIR(K.ESIMO.MENOR(SI($A$1:$A$6=C1,ABS(D1-$B$1:$B$6)),1),SI($A$1:$A$6=C1,ABS(D1-$B$1:$B$6)),0))

(Matricial)

La fórmula es para la fila 1. Para las demás filas debería bastar con copiarla y pegarla hacia abajo.


Saludos.
Usuario
 

Buenos días Experto jrgces, funciono perfectamente, gracias por tu apoyo, en realidad me tomo algo de tiempo encontrar la fórmula correcta, y gracias a ti lo logre, aprovechando el momento te deseo felices fiesta decembrinas, estamos en contacto amigo. Saludos