UserForm no cambie de hoja

Tengo un UserForm para dar de alta, editar y eliminar registros en una hoja de excel, pero deseo abrirlo (el UserForm) desde otra hoja, mi prblema es que al cargar los registros al ComboBox y elegir una entrada, se cambia de hoja a la hoja donde inicialmente lo tenia, se puede evitar esto, es decir ¿qué todo lo haga desde la hoja donde se abre?

Respuesta
2

Pon aquí el código para realizar los ajustes.

Private Sub cmd_Agregar_Click()
Dim i As Integer
If cbo_Nombre.Text = "" Then
MsgBox ZNOVALIDO, vbInformation + vbOKOnly, ZCOPYRIGHT
cbo_Nombre.SetFocus
Exit Sub
End If
If Not (Mid(cbo_Nombre.Text, 1, 1) Like "[a-z]" Or Mid(cbo_Nombre.Text, 1, 1) Like "[A-Z]") Then
MsgBox ZNOVALIDO, vbInformation + vbOKOnly, ZCOPYRIGHT
cbo_Nombre.SetFocus
Exit Sub
End If
For i = 2 To Len(cbo_Nombre.Text)
If Mid(cbo_Nombre.Text, i, 1) Like "#" Then
MsgBox ZNOVALIDO, vbInformation + vbOKOnly, ZCOPYRIGHT
cbo_Nombre.SetFocus
Exit Sub
End If
Next
Sheets("Clientes").Activate
Dim fCliente As Integer
fCliente = nCliente(cbo_Nombre.Text)
If fCliente = 0 Then
Do While Not IsEmpty(ActiveCell)
ActiveCell.Offset(1, 0).Activate ' si el registro no existe, se va al final.
Loop
Else
Cells(fCliente, 1).Select ' cuando ya existe el registro, cumple esta condición.
End If
'Aqui es cuando agregamos o modificamos el registro
Application.ScreenUpdating = False
ActiveCell = cbo_Nombre
ActiveCell.Offset(0, 1) = txt_Direccion
ActiveCell.Offset(0, 2) = txt_Colonia
ActiveCell.Offset(0, 3) = txt_Ciudad
ActiveCell.Offset(0, 4) = txt_CP
ActiveCell.Offset(0, 5) = txt_Telefono
ActiveCell.Offset(0, 6) = txt_RFC
ActiveCell.Offset(0, 7) = txt_Proveedor
Application.ScreenUpdating = True
LimpiarFormulario
cbo_Nombre.SetFocus

End Sub
Private Sub cmd_Eliminar_Click()
Dim fCliente As Integer
fCliente = nCliente(cbo_Nombre.Text)
If fCliente = 0 Then
MsgBox ZNOEXISTE, vbInformation + vbOKOnly, ZCOPYRIGHT
cbo_Nombre.SetFocus
Exit Sub
End If
If MsgBox(ZELIMINAR, vbQuestion + vbYesNo, ZCOPYRIGHT) = vbYes Then
Cells(fCliente, 1).Select
ActiveCell.EntireRow.Delete
LimpiarFormulario
MsgBox ZELIMINADO, vbInformation + vbOKOnly, ZCOPYRIGHT
cbo_Nombre.SetFocus
End If
End Sub
Private Sub cmd_Cerrar_Click()
End
End Sub
Private Sub cbo_Nombre_Change()
On Error Resume Next


If nCliente(cbo_Nombre.Text) <> 0 Then
Sheets("Clientes").Activate
Cells(cbo_Nombre.ListIndex + 6, 1).Select
txt_Direccion = ActiveCell.Offset(0, 1)
txt_Colonia = ActiveCell.Offset(0, 2)
txt_Ciudad = ActiveCell.Offset(0, 3)
txt_CP = ActiveCell.Offset(0, 4)
txt_Telefono = ActiveCell.Offset(0, 5)
txt_RFC = ActiveCell.Offset(0, 6)
txt_Proveedor = ActiveCell.Offset(0, 7)
Else
txt_Direccion = ""
txt_Colonia = ""
txt_Ciudad = ""
txt_CP = ""
txt_Telefono = ""
txt_RFC = ""
txt_Proveedor = ""
End If
End Sub
Private Sub cbo_Nombre_Enter()
CargarLista
End Sub
Sub CargarLista()
cbo_Nombre.Clear
Sheets("Clientes").Select
Range("A6").Select
Do While Not IsEmpty(ActiveCell)
cbo_Nombre.AddItem ActiveCell.Value
ActiveCell.Offset(1, 0).Select
Loop
End Sub

Sub LimpiarFormulario()
CargarLista
cbo_Nombre = ""
txt_Direccion = ""
txt_Colonia = ""
txt_Ciudad = ""
txt_CP = ""
txt_Telefono = ""
txt_RFC = ""
txt_Proveedor = ""
End Sub

¿Es todo el código?

¿Tienes evento UserForm_Activate o UserForm_Initialize?

nCliente es una función: 

fCliente = nCliente(cbo_Nombre.Text)

Puedes poner aquí la función.

-----

NOTA: Para insertar código en el foro, utiliza el icono para insertar código.

Sustituye todo tu código por lo siguiente:

Dim sh As Worksheet
'
Private Sub cmd_Agregar_Click()
  Dim i As Long, lr As Long
  Dim f As Range
  '
  If cbo_Nombre.Text = "" Then
    MsgBox ZNOVALIDO, vbInformation + vbOKOnly, ZCOPYRIGHT
    cbo_Nombre.SetFocus
    Exit Sub
  End If
  If Not (Mid(cbo_Nombre.Text, 1, 1) Like "[a-z]" Or Mid(cbo_Nombre.Text, 1, 1) Like "[A-Z]") Then
    MsgBox ZNOVALIDO, vbInformation + vbOKOnly, ZCOPYRIGHT
    cbo_Nombre.SetFocus
    Exit Sub
  End If
  For i = 2 To Len(cbo_Nombre.Text)
    If Mid(cbo_Nombre.Text, i, 1) Like "#" Then
      MsgBox ZNOVALIDO, vbInformation + vbOKOnly, ZCOPYRIGHT
      cbo_Nombre.SetFocus
      Exit Sub
    End If
  Next
  Set f = sh.Range("A:A").Find(cbo_Nombre.Value, , xlValues, xlWhole, , , False)
  If f Is Nothing Then
    lr = sh.Range("A" & Rows.Count).End(3).Row + 1 'cuando no existe
  Else
    lr = f.Row ' cuando ya existe el registro
  End If
  'Aqui es cuando agregamos o modificamos el registro
  sh.Range("A" & lr).Value = cbo_Nombre
  sh.Range("B" & lr).Value = txt_Direccion
  sh.Range("C" & lr).Value = txt_Colonia
  sh.Range("D" & lr).Value = txt_Ciudad
  sh.Range("E" & lr).Value = txt_CP
  sh.Range("F" & lr).Value = txt_Telefono
  sh.Range("G" & lr).Value = txt_RFC
  sh.Range("H" & lr).Value = txt_Proveedor
  LimpiarFormulario
  cbo_Nombre.SetFocus
End Sub
'
Private Sub cmd_Eliminar_Click()
  Dim f As Range
  Set f = sh.Range("A:A").Find(cbo_Nombre.Text, , xlValues, xlWhole, , , False)
  If f Is Nothing Then
    MsgBox ZNOEXISTE, vbInformation + vbOKOnly, ZCOPYRIGHT
    cbo_Nombre.SetFocus
    Exit Sub
  End If
  If MsgBox(ZELIMINAR, vbQuestion + vbYesNo, ZCOPYRIGHT) = vbYes Then
    f.EntireRow.Delete
    LimpiarFormulario
    MsgBox ZELIMINADO, vbInformation + vbOKOnly, ZCOPYRIGHT
    cbo_Nombre.SetFocus
  End If
End Sub
'
Private Sub cmd_Cerrar_Click()
  End
End Sub
'
Private Sub cbo_Nombre_Change()
  Dim lr As Long
  '
  If cbo_Nombre.ListIndex > -1 Then
    lr = cbo_Nombre.ListIndex + 6
    txt_Direccion = sh.Range("B" & lr).Value
    txt_Colonia = sh.Range("C" & lr).Value
    txt_Ciudad = sh.Range("D" & lr).Value
    txt_CP = sh.Range("E" & lr).Value
    txt_Telefono = sh.Range("F" & lr).Value
    txt_RFC = sh.Range("G" & lr).Value
    txt_Proveedor = sh.Range("H" & lr).Value
  Else
    txt_Direccion = ""
    txt_Colonia = ""
    txt_Ciudad = ""
    txt_CP = ""
    txt_Telefono = ""
    txt_RFC = ""
    txt_Proveedor = ""
  End If
End Sub
'
Private Sub cbo_Nombre_Enter()
  CargarLista
End Sub
'
Sub CargarLista()
  cbo_Nombre.Clear
  cbo_Nombre.List = sh.Range("A6", sh.Range("A" & Rows.Count).End(3)).Value
End Sub
'
Sub LimpiarFormulario()
  CargarLista
  cbo_Nombre = ""
  txt_Direccion = ""
  txt_Colonia = ""
  txt_Ciudad = ""
  txt_CP = ""
  txt_Telefono = ""
  txt_RFC = ""
  txt_Proveedor = ""
End Sub
'
Private Sub UserForm_Activate()
  Set sh = Sheets("Clientes")
End Sub

[Prueba y me comentas...

Function nCliente(nombre As String) As Integer
    Sheets("Clientes").Activate
    Range("A4").Activate
    nCliente = 0
    Do While Not IsEmpty(ActiveCell)
        If nombre = ActiveCell Then
            nCliente = ActiveCell.Row
        End If
        ActiveCell.Offset(1, 0).Select
    Loop
End Function

esta es la funcion

Con el código que te puse no es necesaria la función, estoy utilizando el método Find para encontrar al cliente.

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas

Ejecutar macro si en la celda B1 hay datos

Esta es la macro que utilizo siempre, pero tengo la dificultad que a veces me olvido de colocar el numero de curso (Ejp. 1era_1era o 2da_2da ...)en la celda B1, todo este proceso se ejecuta en la hoja Activa "Curso", lo que busco que la macro se...
2 respuestas

¿Qué hay de mal en este macro?

Quiero hacer un macro para hacer un filtro de una base de datos poniendo como condición un periodo de tiempo, teniendo una celda como fecha de inicio y otra celda como fecha de terminación. Te mando imagen de mi libro y código. Muchas gracias Sub...
1 respuesta

Need a good construction contractor for a home renovation project?

Interested in the uk area. Building a home will be a great investment and dream of their life for most of the people. It is really important to choose the best building contractor for this work. Choosing the right, trustworthy professional contractor...
7 respuestas

Saber el último precio de cierre de cada uno de los valores que compone una cartera de acciones y reflejarlos en un textBox.

Estoy construyendo un formulario para que se vuelque los datos de aquellos la situación de una cartera compuesta por acciones. Es un formulario único pero al clikear en un botón comando se abre un formulario continuo. La situación en la que estoy...
1 respuesta

Como puedo borrar registros relacionados desde un formulario

Tengo un formulario en donde tengo varios registros relacionados, deseo borrar cualquiera de esos registros pero me dice que no puedo borrar registros relacionados, quisiera saber si hay alguna opción con la que pueda borrar.
2 respuestas

Dividir un valor en excel y que el resultado sea igual al de una calculadora manual

Sres. T.E La Consulta es la siguiente: Como dividir 4.888,00 / 30 y que el resultado sea igual tanto en excel como una calculadora manual o la calculado de win xp. Ejemplos: En excel 2003 si divido 4.888,00 / 30 = 162,93 En una Calculadora 4.888,00 /...
2 respuestas

Poner contraseña a una BD de access.

A ver si podéis ayudarme en la siguiente cuestión. Trato de establecer contraseña para la base de datos y no puedo porque aparece un mensaje diciendo que el cifrado de bloques no es compatible con el bloqueo por filas. ¿Cómo puedo arreglar esto?.
2 respuestas

No puedo registrar más de 30k renglones, sale error de desbordamiento (Error 6)

Tengo el siguiente código, que de un formulario pasa los datos a una tabla. El problema es que después de aprox. 35,000 renglones registrados, al querer seguir registrando me aparece el error de desbordamiento (Error 6). Comparto código, si de favor...
3 respuestas

¿Puedo mostrar un subformulario diferente según el valor de un campo para un registro access?

Necesito mostrar un subformulario diferente, según el valor de un campo que llamo "Hecho Extraordinario". Si el hecho es un accidente de transito quiero captar los nombre de los heridos, fallecidos, etc. Si el hecho es un robo de ganado poder captar...
2 respuestas

Error en código para columna de una consulta

Un gusto saludarlos. Quería solicitar su ayuda, porque necesito crear una columna calculada dentro de una consulta access y para eso uso el siguiente código. Saldofinal: IIf(([Nivel]=1 Or [Nivel]=5), ([Sumadesaldoinicial]+[Sumadebe]-[Sumahaber]),...
2 respuestas