Repetir filas inferiores al imprimir en excel

Prueba la siguiente macro.

Primero, crea una hoja llamada "Formato", en esta hoja vas a poner la estructura de la Factura, ancho de columnas, alto de filas, formato de celdas, etc, etc.

'Guardar la informacion
Private Sub Btn_Aceptar_Click()
  Dim hfv As Worksheet, frm As Worksheet
  Dim validarfecha As Boolean
  Dim i As Long, j As Long, k As Long, m As Long, n As Long, p As Long
  Dim pag As Long, lin As Long, fila As Long, x As Long, y As Long
  Dim subtot As Double, wtotal As Long
  Dim buscoit As Range
  '
  If TextBox7 = "" Then     'nro de fact
    MsgBox "Introduzca NRO.DE FACTURA", , "Gilber dice:"
    TextBox7.SetFocus
    Exit Sub
  End If
  '
  Application.ScreenUpdating = False
  Set hfv = Sheets("Factura")
  Set frm = Sheets("Formato")
  '
  'limpiar factura
  hfv.Cells.Clear
  hfv.DrawingObjects.Delete
  'Generar páginas de la factura
    n = ListBox2.ListCount
    pag = WorksheetFunction.RoundUp(n / 16, 0)
    m = 1
    For k = 1 To pag
      'copia valores, imágenes y formatos
 frm. Range("A1:N55"). Copy hfv.Range("A" & m)
      'Ajusta ancho de columnas
      Frm. Range("A1:N55"). Copy
      Hfv.Range("A" & m). PasteSpecial xlPasteColumnWidths
      'Ajusta alto de filas
      p = m
      For lin = 1 To 55
        hfv.Range("A" & p).RowHeight = frm.Range("A" & lin).RowHeight
        p = p + 1
      Next
      'Llenar encabezado
        'Consecutivo
          hfv.Range("I" & m + 9) = "AB - " & TextBox7.Value  'Nro FV
        '... Poner aquí los datos que van en el encabezado
        '
      '
      m = m + 55
    Next
  'Fin generar páginas
  '
  'Llena el detalle de cada página de la factura
  fila = 20
  y = 1
  With ListBox2
    j = fila
    For i = 0 To .ListCount - 1
      x = x + 1
      If x = 17 Then
        x = 1
        fila = fila + 55
        j = fila
        y = y + 1
        subtot = 0
      End If
      hfv.Cells(j, 1) = .List(i, 0)      'cod
      hfv.Cells(j, 5) = .List(i, 1)      'Cantidad
      hfv.Cells(j, 3) = .List(i, 2)      'Descripcion
      hfv.Cells(j, 7) = .List(i, 3)      'Vr.Unitario
      'pasa unid e iva del item
      Set buscoit = hoja2.Range("A:A").Find(Val(ListBox2.List(i, 0)), , xlValues, xlWhole)
      If Not buscoit Is Nothing Then
        hfv.Cells(j, 8) = buscoit.Offset(0, 6).Value / 100 'IVA
      End If
      'Calcular Vr.Total de la linea item * cantidad
      hfv.Cells(j, 11) = Round(hfv.Range("E" & j) * hfv.Range("G" & j) / (1 + hfv.Range("H" & j)), 0)
      subtot = subtot + hfv.Cells(j, 11)
      wtotal = wtotal + hfv.Cells(j, 11)
      j = j + 1
      '
      'filas inferiores
        If y < pag Then
          hfv.Range("C" & fila + 17).Value = "CONTINÚA EN LA SIGUIENTE PÁGINA"
          hfv.Range("H" & fila + 17).Value = subtot
        Else
          hfv.Range("C" & fila + 17).Value = "SON: .... PESOS"
          hfv.Range("H" & fila + 17).Value = wtotal
        End If
      '
    Next
  End With
  Application.ScreenUpdating = True
End Sub

Prueba con 5 items, con 23 items, con 100 items.

La macro en automático creará en la hoja "Factura" el número de páginas y llenará cada página de cada factura.

Falta afinar algunos detalles, como los datos del encabezado, los datos de las filas inferiores. Pero ya está el diseño para crear las páginas y llenarlas.

Te anexo mi archivo de prueba. Puedes llenar el número de items en la hoja "Ejemplo". Ahí puedes poner 1 item o 100 items.

Ejecuta el formulario y presiona el botón para llenar la hoja factura.

https://drive.google.com/file/d/14Thb38CNTcXIfw0q6V6qVLnHIkJC4XsK/view?usp=sharing