Macro copiar pegar tabla dinámica en correo

Lo que hace el código es copiar el rango de excel y pegar en el cuerpo del correo.

Cambia tu código por el siguiente y realiza una prueba. Lo que ahora hace es convertir el rango como html y ponerlo en el cuerpo del correo.

Si te funciona, cambia .Display por .Send para enviar el correo.

Sub Workbook_Open()
    ' Bajado de todoexpertos.com
    Set h = Worksheets("SEGUIMIENTO")
    If CDate(h.Cells(3, "Z")) < Date And h.Cells(50, "E") > 0 Then 'condición
        Call Mail_Selection_Range_Outlook_Body(h)
    End If
    h.Cells(3, "Z") = Date
End Sub
'
Sub Mail_Selection_Range_Outlook_Body(h)
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
'Don't forget to copy the function RangetoHTML in the module.
'Working in Excel 2000-2016
    Dim rng As Range
    Dim OutApp As Object
    Dim OutMail As Object
    Set rng = Nothing
    On Error Resume Next
    ultima_fila = h.Range("B" & Cells.Rows.Count).End(xlUp).Row
    Set rng = h.Range("B5:D" & ultima_fila) '.SpecialCells(xlCellTypeVisible)
    On Error GoTo 0
    If rng Is Nothing Then
        MsgBox "The selection is not a range or the sheet is protected" & _
               vbNewLine & "please correct and try again.", vbOKOnly
        Exit Sub
    End If
    With Application
        .EnableEvents = False
        .ScreenUpdating = False
    End With
    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)
    On Error Resume Next
    With OutMail
        .To = "[email protected]"
        .CC = "[email protected]"
        .BCC = ""
        .Subject = "SEGUIMIENTO A COTIZACIONES, " & Date
        cuerpo = "Por favor realizar seguimiento a la confirmación del cliente, " & _
            h.Cells(50, "E") & " " & "por vencer." & "<br>" & "<br>" & _
            "Atentamente," & "<br>" & "Atención al Cliente" & "<br>"
        .HTMLBody = cuerpo & RangetoHTML(rng)
        .Display
    End With
    On Error GoTo 0
    With Application
        .EnableEvents = True
        .ScreenUpdating = True
    End With
    Set OutMail = Nothing
    Set OutApp = Nothing
End Sub
'
Function RangetoHTML(rng As Range)
' Changed by Ron de Bruin 28-Oct-2006
' Working in Office 2000-2016
    Dim fso As Object
    Dim ts As Object
    Dim TempFile As String
    Dim TempWB As Workbook
    TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"
    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With
    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With
    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")
    'Close TempWB
    TempWB.Close savechanges:=False
    'Delete the htm file we used in this function
    Kill TempFile
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

[Si te ayudó la información, no olvides valorar la respuesta.

Completo y complejo el nuevo código. El que armé/conseguí no se puede modificar y mejorarlo?

Así es. Es bastante complejo, pero el que tu tienes es bastante inestable, todo depende de la velocidad de tu equipo, de la memoria, de la versión de office, etc.

Prueba el nuevo código, qué importa si es muy complejo, no tienes que crearlo, ya hice los cambios para que funcione con tu hoja y tu rango de tabla dinámica.

Muchas gracias Dam, solo un último favor. Hay forma de colocar la tabla antes del texto o entre el mismo?

Con gusto te ayudo con todas tus peticiones, valora la respuesta.