Guardar archivo con campos ingresados

H  o l a:

Te anexo la macro. Cambia "B7" y "F3" por las celdas de proveedor y fecha.

También cambia en la macro "Hoja1" por el nombre de la hoja que quieres guardar. La macro te creará una copia de la hoja en un nuevo libro, el nuevo libro será guardado con el nombre del proveedor y la fecha.

Sub GuardarArchivo()
'Por.Dante Amor
    Application.ScreenUpdating = False
    ruta = ThisWorkbook.Path & "\"
    hoja = "Hoja1"      'Nombre de la hoja a guardar
    prov = "B7"         'celda del proveedor
    fecha = "F3"        'celda de la fecha
    '
    If Range(prov) = "" Then
        MsgBox "Falta ingresar el proveedor", vbExclamation
        Exit Sub
    End If
    If Range(fecha) = "" Then
        MsgBox "Falta ingresar la fecha", vbExclamation
        Exit Sub
    End If
    If Not IsDate(Range(fecha)) Then
        MsgBox "No es una fecha correcta", vbExclamation
        Exit Sub
    End If
    '
    arch = Range(prov) & "-" & Format(Range(fecha), "yymmdd")
    Sheets(hoja).Copy
    ActiveWorkbook.SaveAs _
        Filename:=ruta & arch, _
        FileFormat:=xlOpenXMLWorkbook, CreateBackup:=False
    '
    ActiveWorkbook.Close
    Application.ScreenUpdating = True
    MsgBox "Archivo guardado con el nombre: " & arch
End Sub

Prueba y me comentas si necesitas algo más.

'S aludos. Dante Amor. Recuerda valorar la respuesta. G racias

Para hacer lo que quieres te servirá:

Sub guardar()

ruta = "C:\Users\vrodriguez\Desktop\"

nombre = Range("A1").Value & " " & Range("B1").Value & ".xlsm"

ActiveWorkbook.SaveAs Filename:=ruta & nombre

End Sub

En donde en ruta debes poner la ruta que desees (no te olvides la última contrabarra)

Y A1 y B1 lo deberás cambiar por las celdas donde tienes el nombre del proveedor y la fecha