Reemplazar un titulo al interior de un documento

Puedes usar un documento con una MACRO que vaya abriendo tus archivos y sí encuentra el Titulo lo reemplace y guarde los cambios.
Ejemplo:
Sub AbreDocumento()
'Siempre es preferible declarar las variables que usemos
Dim MiRuta As String
Dim ArchAct As String
Dim sDocNvo As Document
MiRuta = ActiveDocument.Path
ArchAct = ActiveDocument.Name
Dim Arch As String
Arch = Dir(MiRuta & "\*.doc") 'la extensión puede variar dependiendo de tu versión de Word
Do Until Arch = ""
If Arch = ArchAct Then GoTo Salto
Documents.Open FileName:=MiRuta & "\" & Arch
Set sDocNvo = Documents(Arch)
If RemplazaTitulo(sDocNvo, "PREGUNTAS PARA CLASES TEÓRICAS DEL MÓDULO: ESTRATEGIAS DE APRENDIZAJE", "PREGUNTAS DEL CURSO ESTRATEGIAS DE APRENDIZAJE") Then
    sDocNvo.Close SaveChanges:=True
Else
    sDocNvo.Close SaveChanges:=False
End If
Set sDocNvo = Nothing
Salto:
Arch = Dir
Loop
End Sub
Function RemplazaTitulo(ByVal sDoc As Document, ByVal sTituloAnt As String, ByVal sTituloNvo As String) As Boolean
Dim sParrafo As Paragraph
RemplazaTitulo = False
'Aquí se busca y reemplaza el titulo
For Each sParrafo In sDoc.Paragraphs
    If InStr(1, sParrafo.Range.Text, sTituloAnt) > 0 Then
        sParrafo.Range.Text = Replace(sParrafo.Range.Text, sTituloAnt, sTituloNvo)
        RemplazaTitulo = True
    Exit For
    End If
Next
End Function

Doy las gracias, pero es demasiado complejo para mi y no se que ni como hacer lo que sugieres, de antemano gracias.

Ok, entonces si gustas te puedo enviar el documento con la macro y lo único que tienes que hacer copiarlo al mismo directorio donde tienes los demás.
mi correo es [email protected]

Buen día
Acabo de enviar la solicitud a vuestro correo.
Cordialmente
Andrés Castillo