Macro VBA Excel: Numerar celdas visibles
Hice una macro para numerar las celdas visibles filtrando por la columna B. Hasta ahí todo bien. El caso es que que quiero que me numere por cada grupo en columna A, hasta ahí también lo hice. Pero el problema es que a partir del segundo grupo no se numeran de nuevo desde 1, lo hacen como en la foto que adjunto y no encuentro el modo de que quede como indico en la flecha. Os dejo el código por si alguien me lo puede corregir.
Muchas gracias de antemano.
Sub NumerarIO()
Dim ID
Dim ContarI As Long, ContarO As Long
Application.ScreenUpdating = False
For i = 2 To Range("A" & Rows.Count).End(xlUp).Row
If Not Range("A" & i) = ID Then
ID = Range("A" & i)
End If
Select Case Cells(i, 2)
Case ""
Cells(i, 3) = ""
Case "I"
ContarI = ContarI + 1
Cells(i, 3) = ContarI
Case "O"
ContarO = ContarO + 1
Cells(i, 3) = ContarO
End Select
Nex
End Sub
1 Respuesta
Respuesta de Dante Amor
2
Me parece que solamente hay que reiniciar los contadores. Prueba y me comentas:
Sub NumerarIO()
Dim ID, i
Dim ContarI As Long, ContarO As Long
Application.ScreenUpdating = False
For i = 2 To Range("A" & Rows.Count).End(xlUp).Row
If Not Range("A" & i) = ID Then
ID = Range("A" & i)
ContarI = 0
ContarO = 0
End If
Select Case Cells(i, 2)
Case ""
Cells(i, 3) = ""
Case "I"
ContarI = ContarI + 1
Cells(i, 3) = ContarI
Case "O"
ContarO = ContarO + 1
Cells(i, 3) = ContarO
End Select
Next
End Sub
