¿Cómo buscar datos múltiples en dos hojas distintas?
Busco como extraer la información si esta se repite ejemplo
En mi hoja 1 tengo un numero 1232 y en la hoja 2 el mismo numero repetido n veces pero en la columna b traer el dato distito o igual
1232 almacen
1232 almacen
1232 2/02/2021
Busco la forma de extraer esos datos de la hoja 2 a la hoja 1 pero en lista hacia la derecha ya que en la hoja 1 el listado es hacia abajo y requiero que salga de la siguiente forma si es posible
1232 almacen almacen 02/02/2021
Respuesta de Dante Amor
1
En mi hoja 1 tengo un numero 1232
Asumiendo que se llama "Hoja1", que los números están en la columna A y empiezan en la celda A2.
Y en la hoja 2 el mismo numero
Y también asumiendo que se llama "Hoja2" y que los números están en la columna A.
Prueba la siguiente macro:
Sub Datos_Multiples()
'Por Dante Amor
Dim sh1 As Worksheet, sh2 As Worksheet
Dim i As Long, j As Long
Dim f As Range, r As Range
Dim cell As String
Set sh1 = Sheets("Hoja1")
Set sh2 = Sheets("Hoja2")
Set r = sh2.Range("A:A")
For i = 2 To sh1.Range("A" & Rows.Count).End(3).Row
j = 2
Set f = r.Find(sh1.Range("A" & i).Value, , xlValues, xlWhole, , , False)
If Not f Is Nothing Then
cell = f.Address
Do
sh1.Cells(i, j).Value = f.Offset(, 1).Value
j = j + 1
Set f = r.FindNext(f)
Loop While Not f Is Nothing And f.Address <> cell
End If
Next
End Sub
