Sustituir Letras por Números en Excel
Estoy necesitando sustituir un código de 3 letras por un número de 3 cifras. Ya teniendo la valoración de cada letra. ¿Qué fórmula puedo aplicar?
2 Respuestas
Gracias Dante.
Lo que requiero es que una formulación identifique el valor de cada letra y lo lleve a número... Ejemplo anexo
Según tu ejemplo, pon la siguiente fórmula en la celda M8
=BUSCARH(IZQUIERDA(L8),$B$4:$K$5,2)&BUSCARH(EXTRAE(L8,2,1),$B$4:$K$5,2)&BUSCARH(DERECHA(L8),$B$4:$K$5,2)
Si utilizas punto y coma ; como separador, entonces utiliza esta fórmula:
=BUSCARH(IZQUIERDA(L8);$B$4:$K$5;2)&BUSCARH(EXTRAE(L8;2;1);$B$4:$K$5;2)&BUSCARH(DERECHA(L8);$B$4:$K$5;2)
Arrastra o copia la fórmula hacia abajo hasta el final de tus códigos con letra.
'S aludos. Dante Amor. Recuerda valorar la respuesta. G racias
.25/11/16
Hola, Elena
Supuse, para contestarte, que al siguiente alfabeto le asignaste un valor de una cifra.
Ejemplo:
Luego, en la celda D5 coloqué tres letras al azar y, a su derecha, la siguiente fórmula:
=BUSCARV(EXTRAE(D5;1;1);$A$1:$B$26;2;0)&BUSCARV(EXTRAE(D5;2;1);$A$1:$B$26;2;0)&BUSCARV(EXTRAE(D5;3;1);$A$1:$B$26;2;0)
[Considera si usas comas o punto y coma para separar argumentos de las funciones. Yo usé ";"]
Como verás, arma un número de tres cifras compuesto por el valor que le hubieras asignado a cada letra.
.
Hola Fernando. Gracias si es lo que buscaba, pero un detalle que no te dije... algunas veces el Código es de 2 ó 3 cifras. Esta fórmula no me da en caso de ser 2 cifras. Existe una forma para que con una fórmula única pueda tener ambas opciones (2 y 3 cifras independientes?). Millón de Gracias
Buenas noches Profesor. Disculpe pero realmente necesito poder colocar desde 2 cifras y hasta 4 cifras, es decir 2, 3 y 4 cifras.
Mil gracias y segura de contar con su ayuda me despido.
Saludos
Elena desde Caracas
.
Buenas noches, Elena
Usa esta, entonces:
=BUSCARV(EXTRAE(D5;1;1);$A$1:$B$26;2;0)&BUSCARV(EXTRAE(D5;2;1);$A$1:$B$26;2;0)&SI(LARGO(D5)>3;BUSCARV(EXTRAE(D5;3;1);$A$1:$B$26;2;0)&BUSCARV(EXTRAE(D5;4;1);$A$1:$B$26;2;0);SI(LARGO(D5)>2;BUSCARV(EXTRAE(D5;3;1);$A$1:$B$26;2;0);"");"")
Escribí esta formula en el celular, asi que puede estar faltando o sobrando algún paréntesis o Coma, pero creo que no.
Pruebalo a ver si es lo que buscabas.
Si profesor me arroja un error. Le anexo pantalla. Mil gracias.
.
Buenas noches, Elena
Tal vez ya lo hayas descubierto, pero se me duplicó la última parte de la fórmula.
Esta es la que resuelve tu segundo planteo:
=BUSCARV(EXTRAE(D5;1;1);$A$1:$B$26;2;0)&BUSCARV(EXTRAE(D5;2;1);$A$1:$B$26;2;0)&SI(LARGO(D5)>3;BUSCARV(EXTRAE(D5;3;1);$A$1:$B$26;2;0)&BUSCARV(EXTRAE(D5;4;1);$A$1:$B$26;2;0);SI(LARGO(D5)>2;BUSCARV(EXTRAE(D5;3;1);$A$1:$B$26;2;0);""))
.
Buenas tardes, Elena
¿Ha funcionado esta fórmula alterativa para ti?
Saludos
Fer
.
Profesor, si muchas Gracias. Excelente. !!! Maravilloso!!! me ayudó mucho. Ahora profesor si quiero colocar ejemplo CAA.RAA = 100.500 (cien Mil Quinientos) ó UA.RAA = 80.500 (Ochenta Mil Quinientos) ... con esta misma fórmula podría?
.
Buenas, Elena
Veo que me lo vas complicando cada vez más.
Para evitar una fórmula aún más larga, compleja y proclive a muchos errores, mi sugerencia es dividir lo complejo. Usaremos aquella misma fórmula que te sugerí dos veces: una para lo que esté a la izquierda del punto y otra para lo que esté a la derecha. Por lo tanto, necesitaremos un par de celdas auxiliares para dividir ese código en dos y otro par para que haga las búsquedas.
Noté en la otra respuesta (que curiosamente ya valoraste (no así la mía)) que tienes la tabla de conversion en formato horizontal, así que adapté aquella fórmula a esa estructura.
Fíjate en la siguiente imagen, una reproducción de aquella planilla:
Como verás, en el cuadro de abajo te aclaro qué hace cada celda.
- En la celda M8 (en celeste), coloca ésta fórmula:
=IZQUIERDA($L8;ENCONTRAR(".";$L8)-1)
Ésta separa los caracteres que estuviesen a la izquierda del punto. Si no hubiese punto, dará error, pero no importa.
- En la celda N8 (en verde), iría esta otra fórmula
=SI(ESERROR(ENCONTRAR(".";$L8));$L8;DERECHA($L8;LARGO($L8)-ENCONTRAR(".";$L8)))
Es similar a la anterior, pero para capturar los caracteres que estuvieran a la derecha del punto.
Pero tiene un control para el caso de que no hubiese un punto de referencia en cuyo caso, tomará los caracteres que encuentre en la celda de la columna L (fijate el 3º ejemplo)
- En la celda O8 (gris), va ésta fórmula:
=VALOR(BUSCARH(EXTRAE(M8;1;1);$B$3:$K$4;2;0)&BUSCARH(EXTRAE(M8;2;1);$B$3:$K$4;2;0)&SI(LARGO(M8)>3;BUSCARH(EXTRAE(M8;3;1);$B$3:$K$4;2;0)&BUSCARH(EXTRAE(M8;4;1);$B$3:$K$4;2;0);SI(LARGO(M8)>2;BUSCARH(EXTRAE(M8;3;1);$B$3:$K$4;2;0);"")))
Es la que te pasé el otro día pero modificada a BUSCARH y a la ubicación de la tabla de referencia, en este caso convirtiendo los caracteres a la izquierda del punto, si los hubiere. Si no, dará error, pero tampoco importa.
- En la celda P8 (en naranja), pones ésta otra, similar a la anterior:
=VALOR(BUSCARH(EXTRAE(N8;1;1);$B$3:$K$4;2;0)&BUSCARH(EXTRAE(N8;2;1);$B$3:$K$4;2;0)&SI(LARGO(N8)>3;BUSCARH(EXTRAE(N8;3;1);$B$3:$K$4;2;0)&BUSCARH(EXTRAE(N8;4;1);$B$3:$K$4;2;0);SI(LARGO(N8)>2;BUSCARH(EXTRAE(N8;3;1);$B$3:$K$4;2;0);"")))
Pero para la columna N, donde están separados los caracteres a la derecha del punto.
- Finalmente, en la celda Q8 (en amarillo), vá la fórmula que arroja el resultado:
=SI(ESERROR(O8);0;O8*1000)+P8
Como notarás captura el error que pudiera haber para los casos que no tienen punto y devuelve la conversión final expresada como un número.
Desde luego, una vez que controles que esto funcione, puedes copiar estas cinco celdas y pegarlas hacia abajo, ocultando -o no- las columnas auxiliares M, N, O y P
Fiuu! Espero haber sido suficientemente claro (me pregunto por qué me cuesta tanto conseguir que me califiquen. Otros, con mucho menos, ya se liberan)
Avísame si te ha funcionado.
Saludos
Fer
.