Contar las filas donde los datos de las columnas no se repitan.
Hola que tal..
Tengo una hoja con varios registros, en la columna D tengo nombres de persona y en la columna BS otros datos los cuales son seleccionados mediante un combo de 6 datos diferentes.
Lo que necesito es contar las actividades donde los datos de las columnas mencionadas no se repitan. Por ejemplo.
1 Jose Béisbol
2 Miguel Fútbol
3 Adrián Fútbol
4 Jose Fútbol
5 Armando Béisbol
6 Abraham Béisbol
7 Jesús Fútbol
8 Jesús Fútbol
El nombre Jose y Jesús se repite, pero el el caso de Jose su actividades son diferentes. Por el contrario Jesús tiene la misma actividad.
El resultado sería Béisbol 3
Fútbol 4
Espero que me puedan ayudar, de antemano muchas gracias
1 respuesta
Gracias por la rápida respuesta..
Es una solución practica y factible.
El problema es que tengo 26 de estas "listas" y constantemente se les agrega nuevos datos.
Un macro seria estupendo para ahorrar tiempo.
Googleando por ahí, encontré uno que marca los duplicados en una columna y es bastante útil, pero no se como hacerlo que interactue con la otra..
De nuevo gracias.
Para hacer la macro dime, cuáles son las columnas que tienen los datos (nombre y actividad) y en dónde quieres el resultado.
Saludos. DAM
Sigue las Instrucciones para un botón y ejecutar la macro
1. Abre tu libro de Excel
2. Para abrir Vba-macros y poder pegar la macro, Presiona Alt + F11
3. En el menú elige Insertar / Módulo
4. En el panel del lado derecho copia la macro
5. Ahora para crear un botón, puedes hacer lo siguiente:
6. Inserta una imagen en tu libro, elige del menú Insertar / Imagen / Autoformas
7. Elige una imagen y con el Mouse, dentro de tu hoja, presiona click y arrastra el Mouse para hacer grande la imagen.
8. Una vez que insertaste la imagen en tu hoja, dale click derecho dentro de la imagen y selecciona Asignar macro / Selecciona: contar
9. Aceptar.
10. Para ejecutarla dale click a la imagen.
Sub contar()
'Por.DAM
Application.ScreenUpdating = False
c1 = "D" 'columna de nombres
c2 = "F" 'columna de actividades
Set h1 = Sheets("Hoja1") 'hoja de datos
Set h2 = Sheets("td") 'hoja de resultado
nom = h1.Range(c1 & "1")
act = h1.Range(c2 & "1")
h = h2.Name
h2.Cells.Clear
h1.Range(c1 & ":" & c1 & "," & c2 & ":" & c2).Copy h2.Range("A1")
h2.Select
uf = Range("A" & Rows.Count).End(xlUp).Row
ActiveSheet.Range("A$1:$B$" & uf).RemoveDuplicates _
Columns:=Array(1, 2), Header:=xlYes
uf = Range("A" & Rows.Count).End(xlUp).Row
ActiveWorkbook.PivotCaches.Create(xlDatabase, _
h & "!R1C1:R" & uf & "C2", _
xlPivotTableVersion12).CreatePivotTable _
TableDestination:=h & "!R1C4", _
TableName:="Tabla dinámica1", _
DefaultVersion:=xlPivotTableVersion12
With ActiveSheet.PivotTables("Tabla dinámica1")
.AddDataField .PivotFields(nom), "Cuenta de " & nom, xlCount
.PivotFields(act).Orientation = xlRowField
.PivotFields(act).Position = 1
.ColumnGrand = False
.CompactLayoutRowHeader = "ACTIVIDAD"
.PivotFields("Cuenta de " & nom).Caption = "CUENTA"
End With
Columns("D:E").Copy
Range("D1").PasteSpecial Paste:=xlPasteValues
Columns("A:C").Delete Shift:=xlToLeft
Range("A1").Select
Application.ScreenUpdating = True
End Sub
Cambia en la macro esta parte
c1 = "D" 'columna de nombres
c2 = "F" 'columna de actividades
Set h1 = Sheets("Hoja1") 'hoja de datos
Set h2 = Sheets("td") 'hoja de resultado
Cambia la "D" por la columna en donde tienes los nombres
La "F" por la de Actividad.
"Hoja1" por el nombre de tu hoja
Crea una hoja que se llame "td", O bien, crea una hoja y pon el nombre que quieras y cambia “td” por el nombre que pusiste.
Saludos. DAM
No olvides finalizar la pregunta.
Excelente...
Es justo lo que necesitaba, este dolor de cabeza se a resuelto. Me sorprende la velocidad de la respuesta y la solución a mi duda, tu respuesta a sido muy clara y la forma de solo tener que modificar unos pocos datos para hacerlo funcionar en otros libros es de lo mejor,
Gracias.
Gran trabajo DAM, sigue asi...
