Hacer que un formulario cuente registros de otro

Supongamos que tu formulario tiene un textbox llamado 'fechaConsulta' donde pones la fecha que quieres consultar y otros dos textbox (horaIni y horaFin) que contienen la hora inicial y final.
En un cuarto controlBox 'numeroLlamadas' presentaremos el número de llamadas entre esas horas del día indicado.
Un posibilidad es incluir este código que ejecuta el procedimiento 'cuentaLlamadas' cada vez que se sale de los campos 'fechaConsulta', 'horaIni' y 'horaFin'.
Option Compare Database
Option Explicit
Private Sub cuentaLlamadas(ByVal fecha As Variant, ByVal horaIni As Variant, ByVal horaFin As Variant)
    ' Este procedimiento cuenta las llamadas ocurridas desde el minuto 00:00 de la hora
' inicial hasta el minuto 59:59 de la hora final, de una fecha determinada
    Dim aux As Variant
    Dim txtWhere As String
    Me.numeroLlamadas = ""
    ' Comprobamos los datos que nos llegan
    If IsNull(fecha) Or IsNull(horaIni) Or IsNull(horaFin) Then Exit Sub
    If Not IsDate(fecha) Or Not IsNumeric(horaIni) Or Not IsNumeric(horaFin) Then Exit Sub
    ' Construimos la condición de los registros a contar
    txtWhere = "format$(fechaLlamada,'yyyymmdd')='" & Format$(fecha, "yyyymmdd") & "' and " & _
               "format$(fechaLlamada,'hh') between " & Format$(horaIni, "00") & " and " & _
                                                       Format$(horaFin, "00")
    aux = DLookup("count(*)", "aaaa", txtWhere) ' Cuenta los registros
    Me.numeroLlamadas = Nz(aux, "") ' Asigna el valor al textbox de salida
End Sub
Private Sub fechaConsulta_LostFocus()
    cuentaLlamadas Me.fechaConsulta, Me.horaIni, Me.horaFin
End Sub
Private Sub horaFin_LostFocus()
    cuentaLlamadas Me.fechaConsulta, Me.horaIni, Me.horaFin
End Sub
Private Sub horaIni_LostFocus()
    cuentaLlamadas Me.fechaConsulta, Me.horaIni, Me.horaFin
End Sub