Calcular mediante fórmula cómo empezó el partido
Tengo esta parte de mi tabla.
Busco una fórmula que me calcule en la columna G si el R.C.D. Mallorca empezó Ganando (g), Perdiendo (p) o Empatando (e) el partido tras el primer gol (lógicamente la "e" solo será cuando acabó 0-0).
Las celdas BM y CK indican los minutos del primer gol de Y y Z respectivamente, pero pueden estar en blanco (si no hubo gol de ese equipo y ser considerados como 0).
Espero que se haya entendido y gracias por cualquier ayuda de antemano.
2 Respuestas
Prueba lo siguiente:
=SI(Y(BM2="";CK2="");"E";SI(Y(BM2>0;CK2="");"G";SI(Y(BM2="";CK2>0);"P";SI(BM2<CK2;"G";"P"))))
El resultado es para el equipo Local
Recomendaciones:
https://m.youtube.com/watch?v=HjacjhcybzA
https://m.youtube.com/watch?v=hUA5rT3EIaw
https://m.youtube.com/watch?v=dy9w9zbkCaw
Sal u dos
Dante Amor
Gracias.
Se me olvidó decir que en la columna BM está siempre el minuto del primer gol del Mallorca y en la CK el del primer gol del rival (y no del local y del visitante). Ya que lo que quiero discernir es si empezó ganando el Mallorca y no el equipo local, creo que lo he solucionado anidando otro SI en la que se establezca si el Mallorca es el local o el visitante y cambiando los "g" y los "p" según el caso.
Me ha quedado algo así y por las pruebas que he hecho creo que funciona:
=SI(Y(Y2="R.C.D. Mallorca");SI(Y(BM2="";CK2="");"e";SI(Y(BM2>0;CK2="");"g";SI(Y(BM2="";CK2>0);"p";SI(BM2<CK2;"g";"p"))));SI(Y(Z2="R.C.D. Mallorca");SI(Y(BM2="";CK2="");"e";SI(Y(BM2>0;CK2="");"g";SI(Y(BM2="";CK2>0);"p";SI(BM2<CK2;"g";"p"))))))
No sé si se puede simplificar en algo.
Mil gracias por la ayuda.
"Se me olvidó decir que en la columna BM está siempre el minuto del primer gol del Mallorca"
Eso simplifica las cosas
=SI(MIN(BM2;CK2)=0;"E";SI(MIN(BM2;CK2)=BM2;"G";"P"))
Si vas a verificar si uno de los 2 equipos es el Mallorca, entonces:
=SI(ESNUMERO(HALLAR("R.C.D. Mallorca";Y2&Z2));SI(MIN(BM2;CK2)=0;"E";SI(MIN(BM2;CK2)=BM2;"G";"P"));"")Sal u dos
Dante Amor
¿Entonces hay partidos donde no está el Mallorca?
Entonces:
=SI(ESNUMERO(HALLAR("R.C.D. Mallorca";Y2&Z2));SI(MIN(BM2;CK2)=0;"E";SI(MIN(BM2;CK2)=BM2;"G";"P"));"")Sal u dos
Dante Amor
Te dejo otra fórmula para resultados de la col Local y también una fórmula si lo que intentas es obtener resultados de cierto equipo, como el R.C.D. Mallorca.
En la imagen las posibles situaciones y sus resultados.
Para indicar resultados del LOCAL (a partir de fila 2)
=SI(Y(BM2="";CK2="");"E";SI(Y(BM2>0;CK2="");"G";SI(Y(BM2="";CK2>0);"P";SI(BM2<CK2;"G";"P"))))
Para indicar resultados del R.C.D.M (a partir de fila 8)
=SI(Y(BM8="";CK8="");"E";SI(Y8="R.C.D.M";SI(O(CK8="";Y(CK8>BM8;BM8<>""));"G";"P");SI(Z8="R.C.D.M";SI(O(BM8="";Y(BM8>CK8;CK8<>""));"G";"P"))))
NOTA: el separador de argumentos utilizado es punto y coma. Ajusta si tienes solo coma.