Extraer datos de una página WEB
Estoy tratando de extraer información de una página WEB, pero no he conseguido hasta ahora.
Lo que he logrado es enviar información y que realice la búsqueda, pero no logro extraer la información que busco.
Mi código es el siguiente.
Sub judicatura()
Dim ie As Object
Set ie = CreateObject("InternetExplorer.application")
ie.Navigate "http://consultas.funcionjudicial.gob.ec/informacionjudicial/public/informacion.jsf"
Do
DoEvents
Loop Until ie.ReadyState = 4 'verifico si cargo correctamente la página
ie.Document.getElementById("form1:txtDemandadoCedula").Value = "1390059694001"
ie.Document.getElementById("form1:butBuscarJuicios").Click
ie.Visible = True
End SubHay dos resultados de esta búsqueda: Impugnación del documento de finiquito y Haberes e indemnizaciones laborales.
En el código está el RUC del demandado y la página donde se busca la información, si lo necesitan.
2 Respuestas
:)
O así:
Sub Judicatura_2()
Dim ie, Tbl, iRow, Tmp
Set ie = CreateObject("InternetExplorer.Application")
ie.Navigate "http://consultas.funcionjudicial.gob.ec/informacionjudicial/public/informacion.jsf"
Do: DoEvents: Loop Until ie.readyState = 4
ie.Document.getElementById("form1:txtDemandadoCedula").Value = "1390059694001"
ie.Document.getElementById("form1:butBuscarJuicios").Click
Application.Wait Now + TimeValue("0:00:01")
Do
Set Tbl = ie.Document.getElementById("form1:dataTableJuicios2")
Loop Until Tbl.readyState = "complete"
Set Tbl = Tbl.getElementsByTagName("tbody")(0)
If InStr(Tbl.innerText, "No se encuentran") > 0 Then
MsgBox Tbl.innerText: GoTo Fin
End If
For Each iRow In Tbl.Rows
With Cells(Rows.Count, "a").End(xlUp)
.Offset(1, 0) = 0 + iRow.Cells(0).innerText
Tmp = Split(iRow.Cells(1).innerText, "/")
.Offset(1, 1) = DateSerial(Tmp(2), Tmp(1), Tmp(0))
.Offset(1, 2) = iRow.Cells(2).innerText
.Offset(1, 3) = iRow.Cells(3).innerText
End With
Next
Fin:
ie.Quit
Set ie = Nothing
End SubSaludos, Mario R.
P.D. ¡Saludos, Abraham!
:)
.
Te lo dejo todo en un "MsgBox"como para que te des idea:
Sub judicatura()
Dim ie As Object
Dim Texto As Object
Dim TextoCompleto As String
Set ie = CreateObject("InternetExplorer.application")
ie.Navigate "http://consultas.funcionjudicial.gob.ec/informacionjudicial/public/informacion.jsf"
Do
DoEvents
Loop Until ie.ReadyState = 4 'verifico si cargo correctamente la página
ie.Document.getElementById("form1:txtDemandadoCedula").Value = "1390059694001"
ie.Document.getElementById("form1:butBuscarJuicios").Click
ie.Visible = True
Application.Wait (Now + TimeValue("0:00:03"))
Set Texto = ie.Document.getElementById("form1:tabBuscaGeneral_content")
TextoCompleto = Texto.innerText
MsgBox TextoCompleto
End SubComentas
Abraham Valencia
¡Gracias! Funciona. Me toca investigar como sacar solo lo que necesito. Pero esto es de gran ayuda
De nada y, mira lo que envía mi gran amigo Mario Rodríguez ya completó todo, ahora es cuestión de que lo analices para que lo repliques en otras ocasiones.
Salu2
Abraham Valencia
Te has vuelto una buena persona Cacho ja ja ja, un abrazo - Abraham Valencia
Siempre lo he sido sólo que ahora lo soy un poco más (Jeje). Otro abrazo. - Mario Rodríguez