Error fórmula del si anidada
Este es mi primer mensaje.
Les pido ayuda con una fórmula del si anidada que he creado, que al cumplir los requisitos por 1 condición funciona, pero al agregar las 12 variables de fórmula del si sale error.
Es una tabla comparativa donde se cumplen 2 requisitos, tipo de trabajo en la columna izquierda y costo energético fila superior, se interceptan y me dan un resultado.
Quisiera saber cual es el error que estoy cometiendo.
Estoy agradecida por leer este post.
Gracias.
=( SI ( Y (F6 = A6 ; G6 = B5 ) ; B6 ) ) ; ( SI(Y(F6=A6;G6=C5);C6));(SI(Y(F6=A6;G6=D5);D6));(SI(Y(F6=A7;G6=B5);B7));(SI(Y(F6=A7;G6=C5);C7));(SI(Y(F6=A7;G6=D5);D7));(SI(Y(F6=A8;G6=B5);B8));(SI(Y(F6=A8;G6=C5);C8));(SI(Y(F6=A8;G6=D5);D8));(SI(Y(F6=A9;G6=C5);C9));(SI(Y(F6=A9;G6=D5);D9))
2 Respuestas
Te propongo la siguiente fórmula es más corta y como puedes ver sirve a tus propósitos
=+INDICE(B3:D5,COINCIDIR(F3,A3:A5,0),COINCIDIR(G3,B2:D2,0))
¡Gracias!
Lo solucione de esta forma
=SI(Y(F6=A6;G6=B5);B6;SI(Y(F6=A6;G6=C5);C6;SI(Y(F6=A6;G6=D5);D6;SI(Y(F6=A7;G6=B5);B7;SI(Y(F6=A7;G6=C5);C7;SI(Y(F6=A7;G6=D5);D7;SI(Y(F6=A8;G6=B5);B8))))))), aùn me falta.
Aprenderé a usar fórmula , aliviana demasiado el tema.
Mil gracias =)
ME FALTARON 3 CONDICIONES =(
Eso pasa con la fórmula si, con la que te propuse te ahorras ese problema, la fórmula busca coincidencias en columnas y filas creas un plano de coordenadas cartesianas que como resultado te envían al valor que corresponde, lo único que tienes que hacer es cuando agregues más condiciones es ampliar el rango de búsqueda y listo.
El problema con tu fórmula es que estás utilizando el símbolo "*" y eso hace multiplicar los resultados, si un resultado es 0 entonces multiplica el valor por cero y el resultado es cero, sin mencionar que te faltan algunos paréntesis y una celda.
Si lo que estás buscando es el valor en la matriz, según la intersección del "Tipo de trabajo" y el "Costo energético".
Eso te daría una fórmulotota como esta:
=SI(Y(F6=A6;G6=B5);B6;SI(Y(F6=A6;G6=C5);C6;SI(Y(F6=A6;G6=D5);D6;SI(Y(F6=A7;G6=B5);B7;SI(Y(F6=A7;G6=C5);C7;SI(Y(F6=A7;G6=D5);D7;SI(Y(F6=A8;G6=B5);B8;SI(Y(F6=A8;G6=C5);C8;SI(Y(F6=A8;G6=D5);D8;SI(Y(F6=A9;G6=B5);B9;SI(Y(F6=A9;G6=C5);C9;SI(Y(F6=A9;G6=D5);D9;"no existe"))))))))))))
Como puedes ver en la imagen, la fórmula busca cada pareja de Tipo y Costo en la matriz y obtiene un resultado
Pero lo recomendable es que utilices unas fórmulas más sencillas. Porque si tuvieras que aumentar los tipos de trabajo o los costos, la fórmula crecería demasiado y excel no la soportaría.
Utilizaremos las siguientes fórmulas, te explico una por una las fórmulas y al final te pongo la fórmula completa.
Lo primero que haremos es encontrar la fila del Tipo de trabajo
En la celda F6 pon el Tipo "50% trabajo - 50% descanso cada hora"
En la celda H8 pon esta fórmula:
=COINCIDIR(F6;A6:A9;0)
Lo que hace la fórmula es buscar la coincidencia del tipo en las celdas de A6 a A9, el resultado que verás es un 3, significa que el resultado está en la tercera fila empezando en A6.
Ahora buscaremos la columna, en la celda G6 escribe el Costo "Liviana Inferior a 375 Kcal/h"
En la celda H9, escribe la siguiente:
=COINCIDIR(G6;B5:D5;0)
Lo que hace la fórmula es buscar la coincidencia en el rango B5 a D5, el resultado es un 1, significa que la coincidencia está en la primer columna del rango de búsqueda, que es la columna B.
Por último enlazaremos las 2 fórmulas anteriores
=DESREF(A5;COINCIDIR(F6;A6:A9;0);COINCIDIR(G6;B5:D5;0))
Lo que hace la fórmula es iniciar en A5 y de ahí desplazarse el número de filas (3) hacia abajo y el número de columnas (1) hacia la derecha. El resultado es 31.4
.
'S aludos. Dante Amor. Recuerda valorar la respuesta. G racias
.
Avísame cualquier duda
.