Error '2185' al ejecutar consultas plasmadas en informes en VBA

Prueba cambiando Text por Value:

Me.Cuadro_combinado0.Value

Hola experto,,,eso fue lo que hice pero no me da resultado, pues al ejectutar la consulta no se hace nada, no arrancan los informes.

Entonces el problema lo tienes en que no se está cumpliendo ninguna de las condiciones que pones en el bloque If Then Else...

Si le pones un punto de interrupción al código, y al ejecutarlo vas pulsando F8, verás si algún If se cumple o no.

El cuadro combinado ¿de dónde coge los valores que muestra? ¿Estás poniendo exáctamente los mismos valores en el código que los que tienes en el cuadro combinado?

Si,, amigo estoy tomando los mismos datos de el cuadro combinado para realizar las validaciones.

Tengo una tabla llamada consultas, las cual trae o alimenta el cuadro combinado,, los registros de dicha tabla son:

Empresa_cliente_con_personas_cliente
Empresa_cliente_con_personas_cliente_y_pagos
Empresa_cliente_con_ personas_cliente_y_honorarios
Empresa_cliente_con_personas_cliente_y_deudor
Empresa_cliente_con_personas_cliente_y_codeudor

Entonces al realizar las validaciones con If anidados  como los siguientes:

If Me.Cuadro_combinado0.Value = "Empresa_cliente_con_personas_cliente" Then
DoCmd.OpenReport "inf_Emppercli", acViewPreview '
Forms![frm_consultas].Visible = False
ElseIf Me.Cuadro_combinado0.Value = "Empresa_cliente_con_personas_cliente_y_pagos" Then
DoCmd.OpenReport "Inf_Empcliepercliepag", acViewPreview '
Forms![frm_consultas].Visible = False
ElseIf Me.Cuadro_combinado0.Value = "Empresa_cliente_con_personas_cliente_y_honorarios" Then
DoCmd.OpenReport "Inf_Empclienpercliehon", acViewPreview '
Forms![frm_consultas].Visible = False
ElseIf Me.Cuadro_combinado0.Value = "Empresa_cliente con personas_cliente y deudor" Then
DoCmd.OpenReport "Inf_Emplcliepercliedeu", acViewPreview '
Forms![frm_consultas].Visible = False
ElseIf Me.Cuadro_combinado0.Value = "Empresa_cliente con personas_cliente y codeudor" Then
DoCmd.OpenReport "Inf_Empcliepercliecoddeu", acViewPreview '
Forms![frm_consultas].Visible = False
End If

Y realizar la ejecución con F8, no me toma ninguno de los If, si cambio .Value por .text me muestra el error 2185.. No se que estará pasando.

Fíjate que ene le código que pones, los valores que toma el cuadro combinado no son los que pones en los bloques IF (te falta en caracter _ en varios de ellos)

Otra cosa, aunque no te resolverá el problema, es mejor que uses un bloque Select case en vez de tantos If Then Else, pues facilita la escritura y lectura del código:

Select Case Me.Cuadro_combinado0

      Case "Empresa_cliente_con_personas_cliente" 
                DoCmd.OpenReport "inf_Emppercli", acViewPreview '
                Forms![frm_consultas].Visible = False
      Case "Empresa_cliente_con_personas_cliente_y_pagos" 
               DoCmd.OpenReport "Inf_Empcliepercliepag", acViewPreview '
               Forms![frm_consultas].Visible = False

...

End Select

Ponme el origen de la fila de tu cuadro combinado, o mejor aún, una imagen de la pestaña datos de sus propiedades, a ver si doy con el problema

¡Ah!, se me acaba de ocurrir, prueba a cambiar el foco a otro control al principio del código.

Si te empeñas en usar .Text, pásale el foco al cuadro combinado antes de los Ifs

Hola experto envio mas bien un video en el que explico lo que usted me solicita, el enlace es el siguiente:

https://www.youtube.com/watch?v=49YHttvzHKM&feature=youtu.be 

De nuevo muchas gracias.

Att. Hernán Camilo

El error lo tienes en que el cuadro combinado el valor que devuelve es el ID, no el nombre de la consulta. Esto lo puedes comprobar fácilmente con un MsgBox Me.Cuadro_Combinado0

Tienes tres formas de arreglarlo:

1º/ Modificar el código sustituyendo los nombres de las consultas por el ID que tengan en la tabla:

Select Case Me.Cuadro_combinado0

      Case 1
                DoCmd.OpenReport "inf_Emppercli", acViewPreview '
                Forms![frm_consultas].Visible = False
      Case 2

               DoCmd.OpenReport "Inf_Empcliepercliepag", acViewPreview '
               Forms![frm_consultas].Visible = False

...

End Select

2º/ Modificando el Select para que coja la columna con el nombre (ten en cuenta que la primera columna tiene el índice 0):

Select Case Me.Cuadro_combinado0.Column(1)

      Case "Empresa_cliente_con_personas_cliente" 
                DoCmd.OpenReport "inf_Emppercli", acViewPreview '
                Forms![frm_consultas].Visible = False
      Case "Empresa_cliente_con_personas_cliente_y_pagos" 
               DoCmd.OpenReport "Inf_Empcliepercliepag", acViewPreview '
               Forms![frm_consultas].Visible = False

...

End Select

3º/ En las propiedades del cuadro combinado, pestaña Datos, cambia el valor de la propiedad Columna Dependiente de 1 a 2. Aunque esta opción ahora no te la recomiendo por si afecta a otras partes de tu aplicación, puedes tenerla en cuenta al diseñar tus formularios.