Necesito un código en visual basic 6.0 para copiar información de celdas en varios textbox

Revisa las siguientes macros, cada macro lleva unos comentarios

Opción1

Private Sub UserForm_Activate()
'Código para textbox y combobox con nombres consecutivos
'Para llenar TextBox1, TextBox2 y TextBox3 con la columna D,E y F
For i = 1 To 3
    Me.Controls("TextBox" & i) = Cells(2, i + 3)
Next
'Para llenar ComboBox1, ComboBox2 y ComboBox3 con la columna G,H y I
For i = 1 To 3
    Me.Controls("ComboBox" & i) = Cells(2, i + 6)
Next
End Sub

Opción2

Private Sub UserForm_Activate()
'Código para textbox y combobox con diferentes nombres
'Para llenar txtfechalec, txtmeslec, txtdia
'poner en un arreglo todos los textbox
tex = Array("txtfechalec", "txtmeslec", "txtdia")
'En otro arreglo poner la columna que corresponde a cada control
col = Array("D", "E", "F")
'Este sería el ciclo
For i = LBound(tex) To UBound(tex)
    Me.Controls(tex(i)) = Cells(2, col(i))
Next
End Sub

Opción3

Private Sub UserForm_Activate()
'Este ciclo es para textbox de diferente nombre
'Y van apareciendo conforme fueron creados, es decir,
'el primer textbox que será llenado fue el primero que se creó
'Empieza en la columna D
i = 4
For Each ctrl In Me.Controls
    If TypeName(ctrl) = "TextBox" Then
        ctrl.Value = Cells(2, i)
        i = i + 1
    End If
Next
End Sub

Te anexo mi archivo para que hagas pruebas

https://www.dropbox.com/s/i6he99ergantb7c/textbox%20carga%20opciones.xlsm

Saludos. DAM
Si es lo que necesitas.