Formula para encontrar los Números repetidos en una lista.
Hola comunidad de todoExpertos, quisiera me ayudaran con esto, agradezco a quien pueda colaborarme; es asi:
tengo una lista de 8 numero cada numero tiene 3 dígitos y un numero al que le llamare base que sera el 436, de la siguiente forma:
436
129
357
034
368
467
078
056
458
la idea es que me devuelva o me muestre solo para tener en cuenta de la lista de los 8 números que tengan el 4, 3, 6 .
en este caso que solo me muestre el 357 por que con referencia al numero base este tiene el 3, el 034 por que con referencia al numero base este tiene el 4 y el 3. El 368 por que con referencia al numero base este tiene el 3y6, el 467 por que con referencia al numero base este tiene el 4y6 el 056 por que con referencia al numero base este tiene el 6 , el 458 por que con referencia al numero base este tiene el 4, y como podemos notar el 129 no lo muestre o lo oculte ya que no tiene ni 4 ni 3 ni 6 del numero base. Asi mismo el 078 que tampoco tiene ningún dígito del numero base.
entonces en referencia a esos números se reduce a 6 quedaría asi:
357
034
368
467
056
458.
utilizo Microsoft Office Profesional plus 2013
1 respuesta
Prueba con la siguiente fórmula matricial (hay que introducirla pulsando mayúsculas control entrada al mismo tiempo), que tendría que ir a partir de la fila 1 de cualquier columna vacía:
=INDICE($A$1:$A$8;K.ESIMO.MENOR(SI(SUSTITUIR(SUSTITUIR(SUSTITUIR($A$1:$A$8;"4";"");"3";"");"6";"")<>""&$A$1:$A$8;FILA($A$1:$A$8));FILA()))
Cuando no queden números que contengan 4, 3 ó 6 la fórmula devolverá el error #¡NUM!, error que se puede evitar complicando un poco más la fórmula para añadirle un SI.ERROR:
=SI.ERROR(INDICE($A$1:$A$8;K.ESIMO.MENOR(SI(SUSTITUIR(SUSTITUIR(SUSTITUIR($A$1:$A$8;"4";"");"3";"");"6";"")<>""&$A$1:$A$8;FILA($A$1:$A$8));FILA()));"")
Gracias por tu ayuda, quizá no me explique bien pero otra vez:
en la celda N2 tengo el numero base 436, y en las celdas N4:N11 los ocho números. y quiero que frente a las celdas N4:N11 o se las celdas O4:O11 se muestren solo los números que contienen al menos un dígito de ese numero base. y aclaro también que ese numero base cambia con frecuencia asi mismo los otros ocho números. asi que cada ves que yo cambio el numero base mediante otra formula los ocho números me cambian. lo que quiero es que frente a esos ocho se me muestren también los que solo tienen al menos un numero del base.
En O4:
=indice($n$4:$n$11;k.esimo.menor(si(sustituir(sustituir(sustituir($n$4:$n$11;extrae($n$2;1;1);"");extrae($n$2;2;1);"");extrae($n$2;3;1);"")<>""&$n$4:$n$11;fila($n$4:$n$11)-3);fila()-3))
y si se necesita evitar que se muestre el error #¡NUM! cuando no quedan más números que contengan los buscados:
=si.error(indice($n$4:$n$11;k.esimo.menor(si(sustituir(sustituir(sustituir($n$4:$n$11;extrae($n$2;1;1);"");extrae($n$2;2;1);"");extrae($n$2;3;1);"")<>""&$n$4:$n$11;fila($n$4:$n$11)-3);fila()-3));"")
Ambas fórmulas son matriciales, por los que hay que introducirlas pulsando mayúsculas control entrada al mismo tiempo.
gracias por la ayuda una ultima vez. al introducir la formula en la celda O4 me devuelve el primer numero de los ocho o se a el 129 y en el resto de las celdas no me muestra nada o sea en las celdas O5:O11.
estas las introduzco pulsando control+mayus al mismo tiempo. y no me devuelve nada. gracias por su ayuda.
Para introducir la fórmula como matricial hay que pulsar mayúsculas control y entrada al mismo tiempo. Si lo hace bien la fórmula debería aparecer en la barra de fórmulas encerrada entre llaves { }
De todas formas he subido un libro con las fórmulas funcionando a http://www.jrgc.es/ejemplos/20130214a.xlsx
