Insertar signo

En realidad no es tan difícil.
Este sería el código a colocar en el panel de macros de la hoja donde el proceso debe ejecutarse:
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
'indica rango donde quieres que ocurra:
Enrango = "B1:B888"
Separa = "-"
If Not Intersect(Target, Range(Enrango)) Is Nothing Then
If Not IsEmpty(Target) Then
If Not Target.HasFormula Then
Application.EnableEvents = False
If IsNumeric(Target) Then
'secuencia de separación del número
Texto = Trim(Target.Value)
If InStr(1, Texto, Separa) = 0 Then 'controla si ya está separado o no
Cadena = ""
For posicion = Len(Texto) To 1 Step -1
Carakter = Mid(Texto, posicion, 1)
Cadena = Carakter & Cadena
If (Len(Texto) - posicion + 1) Mod 3 = 0 And posicion <> 1 Then Cadena = Separa & Cadena
Next
Target.Value = Cadena
End If
End If
Application.EnableEvents = True
End If
End If
End If
End Sub
Verás que solo reemplacé la línea que colocaba el prefijo "F-" por la secuencia de separación del número.
Como sólo debe actuar en la celda activa el ciclo Do...Loop Until no es necesario.
En aquella secuencia reemplacé ActiveCell por Target que serían equivalentes pero conviene aprovechar que VBA detecta cual es la celda donde se hizo el cambio.
Obviamente, le agregué la variable que guarda el separador a usar.
Mantuve los controles de intersección de rangos, de que la celda no haya quedado vacía (cuando borras su contenido) y que la celda no tenga una fórmula.
Y le agregué también un control de que sea un número por si tuvieras que ingresar un texto en aquel rango (en cuyo caso no querrías que lo separe con guiones)
Pruébalo y coméntame si funcioné para ti.
Que tengas un gran fin de semana!
Fernando

Efectivamente, como comentas las opciones funcionan de maravilla ya las puse a funcionar y que decir eres un genio, no quiero terminar esta pregunta sin, aclarar otra duda al respecto, pudiera ser posible ejecutar la macro que enviaste por medio de un evento como fue el caso anterior de "concatenar", y que para tal efecto me enviaste el siguiente código :
Private Sub Worksheet_Change(ByVal Target As Excel.Range)
'indica rango donde quieres que ocurra:
Enrango = "F:F"
If Not Intersect(Target, Range(Enrango)) Is Nothing Then
If Not IsEmpty(Target) Then
If Not Target.HasFormula Then
Application.EnableEvents = False
Target.Value = "F-" & Target
Application.EnableEvents = True
End If
End If
End If
End Sub
Con este código, que enviaste la verdad funciona muy bien y de ser posible quisiera la macro que enviaste se ejecutara por del evento antes señalado
Recibe un fuerte abrazo !
Jose

Supongo, por los ejemplos, que el signo a insertar es el guión, ya que en el enunciado de la pregunta aparecen unos códigos como estos " - &#8220 (comillas y algo entre ellas)
De todos modos la siguiente macro te permite colocar en una variable (separa) el carácter que desees para separar el número:
Sub PoneGuion()
Separa = "-"
Do
'secuencia de separación del número
Texto = Trim(ActiveCell.Value)
If InStr(1, Texto, Separa) = 0 Then 'controla si ya está separado o no
Cadena = ""
For posicion = Len(Texto) To 1 Step -1
Carakter = Mid(Texto, posicion, 1)
Cadena = Carakter & Cadena
If (Len(Texto) - posicion + 1) Mod 3 = 0 And posicion <> 1 Then Cadena = Separa & Cadena
Next
ActiveCell.Value = Cadena
End If
ActiveCell.Offset(1).Select
Loop Until IsEmpty(ActiveCell)
End Sub
---
Este procedimiento coloca el separador indicado cada tres posiciones contados de derecha a izquierda, con lo cual no sólo sirve para números de nueve dígitos sino para otros de cualquier extensión.
Deberás seleccionar la celda con el primer número de la lista y ejecutar la macro PoneGuion.
Esta controla que el número no tenga ya colocado el carácter y se repite hasta encontrar una celda vacía.
---
Explicada la parte difícil de tu pregunta, cabré mencionar que lograrías un efecto similar asignándole a la celda un formato personalizado ("Formato" | "Celda" | "Número" | "Personalizada"") del tipo:
###-###-###
Esto evita modificar el número y lo *muestra* separado con guiones. La ventaja de este método es que es automático (i.e. No hay que ejecutar macro alguna), supuesto que hayas asignado tal formato a la celda previamente.
Espero que te sea de utilidad.
Un abrazo!
Fernando