Cómo quitar tildes (acentos) en campos de texto de una tabla de Access

Una forma de hacerlo "de una pasada" y sin mucha complicación (pero por si las moscas, prueba en una copia de tu BD):

Crea un módulo nuevo en tu BD y en él pega esta función:

'--------------------------------------------------------------------------------------------
'Función para quitar acentos de una cadena de texto
'--------------------------------------------------------------------------------------------
Public Function fncQuitarAcentos(ByVal strTexto As String) As String
Const conAcentos = "ÁÀÂÄÃáàâäãÉÈÊËéèêëÍÌÎÏíìîïÓÒÔÖÕóòôöõÚÙÛÜúùûüÝýÿ"
Const sinAcentos = "AAAAAaaaaaEEEEeeeeIIIIiiiiOOOOOoooooUUUUuuuuYyy"
Dim i As Long
Dim lngPos As Long
Dim strCaracter As String * 1
If Len(strTexto) = 0 Then
fncQuitarAcentos = ""
Exit Function
End If
For i = 1 To Len(strTexto)
strCaracter = Mid(strTexto, i, 1)
'comparamos el caracter con la cadena con acentos
lngPos = InStr(1, conAcentos, strCaracter, vbBinaryCompare)
'si se ha encontrado coincidencia ...
If lngPos <> 0 Then
'sustituímos el caracter con el que tiene la misma
'posición en la cadena sin acentos (o sea la letra sin acentos)
strCaracter = Mid(sinAcentos, lngPos, 1)
End If
'... y si no, pues seguimos como si nada
fncQuitarAcentos = fncQuitarAcentos & strCaracter
Next i
End Function

Guarda los cambios.

Crea una consulta, añade únicamente el campo (o campos) al que le quieres quitar los acentos, convierte la consulta en una consulta de actualización, y en la fila "actualizar a" que te aperecerá, pones, en cada campo:

fncQuitarAcentos([NombreCampo]).

Así como te muestro en la imagen:

Otra forma es que crees directamente la consulta en Vista SQL, por ejemplo:

UPDATE TuTabla SET TuTabla.Campo= fncQuitarAcentos([Campo]);

En tu caso, con dos campos, sería algo así (cambia el nombre de la tabla):

UPDATE TuTabla SET Nombre = fncQuitarAcentos([Nombre]), Apellidos = fncQuitarAcentos([Apellidos])