Crear archivos y que se enumeren

No me había llegado la pregunta. No sé que sistema utiliza la página para comunicar las preguntas a los supuestos "expertos" pero a mí no me la ha mandado. Al entrar "de visita" la he visto.

No acabo de entender para que puede servir tener un número variable de copias, con distinto nombre, de un mismo archivo, pero tampoco hay necesidad de que lo entienda.

Sugiero que el nombre del proyecto sea también un parámetro a pedir. También podría ser un parámetro a pasar en la línea de llamada.

Mira a ver si esto se adapta a vuestras necesidades:

@echo off
set /p ProyN=Nombre del proyecto:
set /p CapN=Numero de capitulos (incluido el cero):
set /p HojN=Numero de hojas/capitulo:
set /a CapN=%CapN% - 1
for /l %%c in (0,1,%CapN%) DO (call :TratCap %%c)
goto :EOF
:TratCap
set cap=%1
if %1 LSS 100 set cap=0%1
if %1 LSS 10 set cap=00%1
for /l %%h in (1,1,%HojN%) DO (call :TratHoj %%h)
goto :EOF
:TratHoj
set hoj=%1
if %1 LSS 100 set hoj=0%1
if %1 LSS 10 set hoj=00%1
copy %ProyN%000001-a.dwg %ProyN%%cap%%hoj%-a.dwg
goto :EOF

Ya me dirás.

Hola el archivo que me has enviado funciona estupendamente.

No se si se podría añadir esto:

Primera pregunta:

Crear  capitulo independiente s/n =  s  elegimos si

Nombre del proyecto = po-oi-14066-d-

Numero de capitulo = 5

Numero de hojas /capitulo = 2

Crear otro capitulo s/n = n

Y nos tendría que quedar así:

po-oi-14066-d-005001-a.dwg

po-oi-14066-d-005002-a.dwg

y si le dices que s  poder crear mas capítulos

si al principio   de la pregunta:

Crear  capitulo independiente s/n =  n  elegimos no

La ejecución del  bat  que sea igual que lo que me  has enviado.

Esto ya sé que parece raro pero tenemos un gestor de planos que  genera  un archivo dwg cargando delas plantillas de cad tarda unos 3 minutos si multiplicamos por 100 archivos son 300 minutos unas 5 horas esto que has hecho es muchísimo mas rápido.

saludos

Respecto a lo que me comentas de la utilidad de este BAT lo que me sorprende es que solo importen los nombres de los archivos y no los contenidos, pero, en todo caso, me alegro de que el sufrido MSDOS todavía sea capaz de ofrecer soluciones útiles.

Si te he entendido bien esto haría lo que pides:

@echo off
set /p Isn=¨Cap¡tulo independiente (S/N)?
set /p ProyN=Nombre del proyecto:
:Bucle
set /p CapN=N£mero Cap¡tulo (incluido el cero):
set /p HojN=N£mero de hojas/cap¡tulo:
if %Isn%==s goto :CapInd
if %Isn%==S goto :CapInd
set /a CapN=%CapN% - 1
for /l %%c in (0,1,%CapN%) DO (call :TratCap %%c)
goto :EOF
:TratCap
set cap=%1
if %1 LSS 100 set cap=0%1
if %1 LSS 10 set cap=00%1
for /l %%h in (1,1,%HojN%) DO (call :TratHoj %%h)
goto :EOF
:TratHoj
set hoj=%1
if %1 LSS 100 set hoj=0%1
if %1 LSS 10 set hoj=00%1
copy %ProyN%000001-a.dwg %ProyN%%cap%%hoj%-a.dwg
goto :EOF
:CapInd
call :TratCap %CapN%
set /p Mas=¨M s cap¡tulos (S/N)?
if %Mas%==s goto :Bucle
if %Mas%==S goto :Bucle

En las preguntas considero "sí" tanto la "s" como la "S" y "no" cualquier otro valor.

Ya me dirás como va.

Hola, ya lo he probado y funciona fenomenal, solo un pero : la primera preguntaque me hace es:

¿  capitulo independiente (s/n)? ----Perfecto elegimos s

Nombre del proyecto ----- perfecto lo ponemos

Numero capitulo (incluido el cero) ---- se podría quitar de esta pregunta el texto (incluido el cero) creo que has hecho una especie de buqule para usar las mismas preguntas en ambos casos pero creo que en esta opción sobra el texto que te indico.

Saludos

Sí, es como dices, intento reutilizar las preguntas, ¡Vago que es uno!

Incluso llegué a quitar la referencia al cero, pero me parecía que se perdía algo de información. Si te vale sin esa parte del texto solo tienes que editar la línea y borrarle lo que consideres que sobra. Si prefieres personalizarla un poco habría que separar cada una de las dos modalidades un poco más, o un poco antes para que cada opción tenga sus propios mensajes.

Creo que ya puedes continuar tú con lo que falta. Si tienes alguna duda, me preguntas, ¿vale?

hola, voy  ha intentar hacerlo tengo todo el fin de semana por delante y muchas gracias por ofrecerte a contestar mis preguntas un  saludo y otra vez  eternamente agradecido.

Entiendo que la pregunta ya la has dado por cerrada (gracias por la valoración de "excelente"). Sin embargo la página me dice que esta pregunta está pendiente de que conteste. Supongo que es algún error interno, pero voy a contestar a ver que pasa.

Aprovecharé para preguntar si conseguiste que funcionara a tu gusto. Y para insistir en que te sientas totalmente libre de preguntarme cualquier cosa.

Hola, no sabia que al votar se cerraba la pregunta lo tendré en cuenta para próximas veces.

Al final no he hecho nadadeloque te comente de separar las preguntas ya que en el trabajo no lo ven. Al finalhemos puesto mayúsculas y cambiado el texto de alguna pregunta y listo.

@echo off
set /p Isn=¨CAPITULO INDEPENDIENTE (S/N)?
set /p ProyN=NOMBRE PROYECTO:
:Bucle
set /p CapN=NUMERO DE CAPITULO/OS:
set /p HojN=NUMERO DE PLANOS/CAPITULO:
if %Isn%==s goto :CapInd
if %Isn%==S goto :CapInd
set /a CapN=%CapN% - 1
for /l %%c in (0,1,%CapN%) DO (call :TratCap %%c)
goto :EOF
:TratCap
set cap=%1
if %1 LSS 100 set cap=0%1
if %1 LSS 10 set cap=00%1
for /l %%h in (1,1,%HojN%) DO (call :TratHoj %%h)
goto :EOF
:TratHoj
set hoj=%1
if %1 LSS 100 set hoj=0%1
if %1 LSS 10 set hoj=00%1
copy %ProyN%000001-A.dwg %ProyN%%cap%%hoj%-A.dwg
goto :EOF
:CapInd
call :TratCap %CapN%
set /p Mas=¨MAS CAPITULOS (S/N)?
if %Mas%==s goto :Bucle
if %Mas%==S goto :Bucle

Si necesitas que vuelva a votar me lo comentas.

Un saludo y muchas gracias