Abrir una carpeta desde un formulario pulsando un botón

Quizá te dé una idea. Si tengo un formulario con un botón, aunque podría ser en cualquier otro evento

Al pulsarlo me abre la carpeta ImagenesUsar

El código del botón es simplemente

Private Sub Comando23_Click()
Application.FollowHyperlink "c:\users\gonza\documents\imagenesusar"
End Sub

Puede utilizar algo como:

Después de elegir la carpeta obtengo:

CÓDIGO DEL BOTÓN abrir carpeta

Private Sub btnElegir_Click()
 Me.ctlCarpeta = selectCarpeta
 If Len(Me.ctlCarpeta) = 0 Then
    Exit Sub
 Else
   Shell ("Explorer " & Me.ctlCarpeta), vbMaximizedFocus
 End If
End Sub

Defina esta función a nivel de formulario:

Function selectCarpeta() As String
    On Error GoTo sol_err
    Dim vFD As Object
    Dim vRutaIni As String
    'Difinimos la ruta inicial
    vRutaIni = Application.CurrentProject.Path ' Puede dejar la carpeta por defecto
    Set vFD = Application.FileDialog(msoFileDialogFolderPicker)
    With vFD
        .Title = "Seleccione la carpeta"
        .ButtonName = "Aceptar"
        .InitialView = msoFileDialogViewList
        .InitialFileName = vRutaIni
        If .Show = -1 Then
            selectCarpeta = CStr(.SelectedItems.Item(1))
        Else
            MsgBox "Ha cancelado la selección", vbOKCancel Or vbExclamation Or vbMsgBoxSetForeground, "Carpeta.."
            Exit Function
        End If
    End With
Salida:
    Exit Function
sol_err:
    MsgBox "Se ha producido un error: " & Err.Number & " - " & Err.Description
    Resume Salida
End Function

No le recomiendo utilizar FollowHyperlink para abrir archivos y carpetas.