Replicacion sql server 2000

Casi no hago replicaciones pero esto te puede ayudar, además puedes checar en la página de microsoft: http://msdn.microsoft.com
Implementing Nonpartitioned, Bidirectional, Transactional Replication
New Information - September 2001.
You can develop a transactional, nonpartitioned, bidirectional application using the following replication features:
Reciprocal publications
Custom stored procedures
Cycle detection
¿The sample application presented in this topic illustrates how these features can be combined programmatically on one Microsoft® SQL Server? installation using two databases (test1 and test2). The sample is built in six steps.
Step 1: Create the Databases and Enable Replication.
Step 2: Create a Bidirectional Schema.
Step 3: Create Reciprocal Publications.
Step 4: Create Subscriptions with Cycle Detection Enabled.
Step 5: Create Custom Stored Procedures to Apply Changes and Handle Conflicts.
Step 6: Test the Application.
See Also
Nonpartitioned, Bidirectional, Transactional Replication
©1988-2001 Microsoft Corporation. All Rights Reserved.
Step 1: Create the Databases and Enable Replication
New Information - September 2001.
To set up bidirectional replication
Create the two databases for your application: test1 and test2.
Enable the server as a Publisher, Subscriber, and Distributor. If the server is already enabled as a Publisher, Subscriber, and Distributor, you can skip this step.
Enable the databases for replication.
Examples
1. Create the test databases
CREATE database test1
CREATE database test2
2. Enable the server as a Publisher, Subscriber, and Distributor
EXEC master..sp_adddistributor @distributor = @@SERVERNAME
GO
EXEC master..sp_adddistributiondb @database= 'distribution'
GO
EXEC master..sp_adddistpublisher @publisher = @@SERVERNAME, @distribution_db = 'distribution', @working_directory = 'C:\Program Files\Microsoft SQL Server\MSSQL\REPLDATA'
GO
EXEC master..sp_addsubscriber @subscriber = @@SERVERNAME, @type = 0, @security_mode = 1
GO
EXEC master..sp_changesubscriber_schedule @subscriber = @@SERVERNAME, @agent_type = 1, @active_end_date = 0
GO
3. Enable the databases for replication
USE master
GO
EXEC sp_replicationdboption N'test1', N'publish', true
GO
EXEC sp_replicationdboption N'test2', N'publish', true
GO
©1988-2001 Microsoft Corporation. All Rights Reserved.
Step 2: Create a Bidirectional Schema
New Information - September 2001.
To create a bidirectional schema, create a table with the same schema in each test database and populate it with sample data.
Examples
1. Create a table in test1 and populate with 10 rows
USE test1
GO
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'two_way_test1')
DROP TABLE two_way_test1
GO
CREATE TABLE two_way_test1
(pkcol int primary key not null,
intcol int,
charcol char(100),
datecol datetime
)
GO
INSERT INTO two_way_test1 VALUES (1, 10, 'row1', GETDATE())
INSERT INTO two_way_test1 VALUES (2, 20, 'row2', GETDATE())
INSERT INTO two_way_test1 VALUES (3, 30, 'row3', GETDATE())
INSERT INTO two_way_test1 VALUES (4, 40, 'row4', GETDATE())
INSERT INTO two_way_test1 VALUES (5, 50, 'row5', GETDATE())
INSERT INTO two_way_test1 VALUES (6, 60, 'row6', GETDATE())
INSERT INTO two_way_test1 VALUES (7, 70, 'row7', GETDATE())
INSERT INTO two_way_test1 VALUES (8, 80, 'row8', GETDATE())
INSERT INTO two_way_test1 VALUES (9, 90, 'row9', GETDATE())
INSERT INTO two_way_test1 VALUES (10, 100, 'row10', GETDATE())
GO
2. Create a table in test2 and populate with 10 rows
USE test2
GO
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'two_way_test2')
DROP TABLE two_way_test2
GO
CREATE TABLE two_way_test2
(pkcol int primary key not null,
intcol int,
charcol char(100),
datecol datetime
)
GO
INSERT INTO two_way_test2 VALUES (1, 10, 'row1', GETDATE())
INSERT INTO two_way_test2 VALUES (2, 20, 'row2', GETDATE())
INSERT INTO two_way_test2 VALUES (3, 30, 'row3', GETDATE())
INSERT INTO two_way_test2 VALUES (4, 40, 'row4', GETDATE())
INSERT INTO two_way_test2 VALUES (5, 50, 'row5', GETDATE())
INSERT INTO two_way_test2 VALUES (6, 60, 'row6', GETDATE())
INSERT INTO two_way_test2 VALUES (7, 70, 'row7', GETDATE())
INSERT INTO two_way_test2 VALUES (8, 80, 'row8', GETDATE())
INSERT INTO two_way_test2 VALUES (9, 90, 'row9', GETDATE())
INSERT INTO two_way_test2 VALUES (10, 100, 'row10', GETDATE())
GO
©1988-2001 Microsoft Corporation. All Rights Reserved.
Step 3: Create Reciprocal Publications
New Information - September 2001.
To create reciprocal publications, add the transactional publication and article to each database. Note that:
Custom stored procedures are used for @ins_cmd, @del_cmd, and @upd_cmd.
The XCALL style parameters are used in UPDATE and DELETE stored procedures. For more information, see Using Custom Stored Procedures in Articles.
@schema_option disables autogeneration of the default custom stored procedures because they will be created in Step 4.
Examples
1. Add the transactional publication and article in test1
USE test1
GO
EXEC sp_addpublication @publication = N'two_way_pub_test1',
@restricted = N'false', @sync_method = N'native',
@repl_freq = N'continuous', @description = N'publ1',
@status = N'active', @allow_push = N'true',
@allow_pull = N'true', @allow_anonymous = N'false',
@enabled_for_internet = N'false',
@independent_agent = N'false', @immediate_sync = N'false',
@allow_sync_tran = N'false',
@autogen_sync_procs = N'false', @retention = 60
GO
EXEC sp_addarticle @publication = N'two_way_pub_test1',
@article = N'two_way_test1', @source_owner = N'dbo',
@source_object = N'two_way_test1',
@destination_table = N'two_way_test2',
@type = N'logbased', @creation_script = null,
@description = null, @pre_creation_cmd = N'drop',
@schema_option = 0x00000000000000F1, @status = 16,
@vertical_partition = N'false',
@ins_cmd = N'CALL sp_ins_two_way_test2',
@del_cmd = N'XCALL sp_del_two_way_test2',
@upd_cmd = N'XCALL sp_upd_two_way_test2',
@filter = null, @sync_object = null
GO
2. Add the transactional publication and article in test2
USE test2
GO
EXEC sp_addpublication @publication = N'two_way_pub_test2',
@restricted = N'false', @sync_method = N'native',
@repl_freq = N'continuous', @description = N'Pub2',
@status = N'active', @allow_push = N'true',
@allow_pull = N'true', @allow_anonymous = N'false',
@enabled_for_internet = N'false',
@independent_agent = N'false', @immediate_sync = N'false',
@allow_sync_tran = N'false',
@autogen_sync_procs = N'false', @retention = 60
GO
EXEC sp_addarticle @publication = N'two_way_pub_test2',
@article = N'two_way_test2', @source_owner = N'dbo',
@source_object = N'two_way_test2', @destination_table =
N'two_way_test1', @type = N'logbased',
@creation_script = null,
@description = null, @pre_creation_cmd = N'drop',
@schema_option = 0x00000000000000F1, @status = 16,
@vertical_partition = N'false',
@ins_cmd = N'CALL sp_ins_two_way_test1',
@del_cmd = N'XCALL sp_del_two_way_test1',
@upd_cmd = N'XCALL sp_upd_two_way_test1',
@filter = null, @sync_object = null
GO
©1988-2001 Microsoft Corporation. All Rights Reserved.
Step 4: Create Subscriptions with Cycle Detection Enabled
New Information - September 2001.
To create subscriptions with cycle detection enabled, add a transactional subscription to each database with @loopback_detection set to TRUE, so that the Distribution Agent does not send transactions that originated at the Subscriber back to the Subscriber.
Examples
1. Add the transactional subscription in test1
USE test1
GO
EXEC sp_addsubscription @publication = N'two_way_pub_test1',
@article = N'all', @subscriber = @@SERVERNAME,
@destination_db = N'test2', @sync_type = N'none',
@status = N'active', @update_mode = N'read only',
@loopback_detection = 'true'
GO
2. Add the transactional subscription in test2
USE test2
GO
EXEC sp_addsubscription @publication = N'two_way_pub_test2',
@article = N'all', @subscriber = @@SERVERNAME,
@destination_db = N'test1', @sync_type = N'none',
@status = N'active', @update_mode = N'read only',
@loopback_detection = 'true'
GO
©1988-2001 Microsoft Corporation. All Rights Reserved.
Step 5: Create Custom Stored Procedures to Apply Changes and Handle Conflicts
New Information - September 2001.
The update procedures in the examples have been customized to detect and handle simple conflicts. If a conflict is detected in the intcol column, the current value and new increment are added together; if a conflict is detected in the charcol field, the values are concatenated together.
Examples
1. Create custom stored procedures in test1
USE test1
GO
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'sp_ins_two_way_test1' and type = 'P')
DROP proc sp_ins_two_way_test1
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'sp_upd_two_way_test1' and type = 'P')
DROP proc sp_upd_two_way_test1
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'sp_del_two_way_test1' and type = 'P')
DROP proc sp_del_two_way_test1
GO
-- Insert procedure
CREATE proc sp_ins_two_way_test1 @pkcol int,
@intcol int,
@charcol char(100),
@datecol datetime
AS
INSERT INTO two_way_test1 (pkcol, intcol, charcol,
datecol)
VALUES (@pkcol, @intcol, @charcol, GETDATE())
GO
-- Update procedure
CREATE proc sp_upd_two_way_test1 @old_pkcol int,
@old_intcol int,
@old_charcol char(100),
@old_datecol datetime,
@pkcol int, @intcol int,
@charcol char(100),
@datecol datetime
AS
-- IF intcol conflict is detected, add values
-- IF charcol conflict detected, concatenate values
DECLARE @curr_intcol int, @curr_charcol char(100)
SELECT @curr_intcol = intcol, @curr_charcol = charcol
FROM two_way_test1 WHERE pkcol = @pkcol
IF @curr_intcol != @old_intcol
SELECT @intcol = @curr_intcol +
(@intcol - @old_intcol)
IF @curr_charcol != @old_charcol
SELECT @charcol = rtrim(@curr_charcol) +
'_' + rtrim(@charcol)
UPDATE two_way_test1 SET intcol = @intcol,
charcol = @charcol, datecol = GETDATE()
WHERE pkcol = @old_pkcol
GO
-- Delete procedure
CREATE proc sp_del_two_way_test1 @old_pkcol int,
@old_intcol int,
@old_charcol char(100),
@old_datecol datetime
AS
DELETE two_way_test1 WHERE pkcol = @old_pkcol
GO
2. Create custom stored procedures in test2
USE test2
GO
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'sp_ins_two_way_test2' and type = 'P')
DROP proc sp_ins_two_way_test2
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'sp_upd_two_way_test2' and type = 'P')
DROP proc sp_upd_two_way_test2
IF EXISTS (SELECT * FROM sysobjects WHERE name LIKE 'sp_del_two_way_test2' and type = 'P')
DROP proc sp_del_two_way_test2
GO
-- Insert procedure
CREATE proc sp_ins_two_way_test2 @pkcol int,
@intcol int,
@charcol char(100),
@datecol datetime
AS
INSERT INTO two_way_test2 (pkcol, intcol, charcol,datecol)
VALUES (@pkcol, @intcol, @charcol, GETDATE())
GO
-- Update procedure
CREATE proc sp_upd_two_way_test2 @old_pkcol int,
@old_intcol int,
@old_charcol char(100),
@old_datecol datetime,
@pkcol int,
@intcol int,
@charcol char(100),
@datecol datetime
AS
-- IF intcol conflict is detected, add values
-- IF charcol conflict detected, concatenate values
DECLARE @curr_intcol int, @curr_charcol char(100)
SELECT @curr_intcol = intcol, @curr_charcol = charcol
FROM two_way_test2 WHERE pkcol = @pkcol
IF @curr_intcol != @old_intcol
SELECT @intcol = @curr_intcol +
(@intcol - @old_intcol)
IF @curr_charcol != @old_charcol
SELECT @charcol = rtrim(@curr_charcol) +
'_' + rtrim(@charcol)
UPDATE two_way_test2 SET intcol = @intcol,
charcol = @charcol, datecol = GETDATE()
WHERE pkcol = @old_pkcol
GO
-- Delete procedure
CREATE proc sp_del_two_way_test2 @old_pkcol int,
@old_intcol int,
@old_charcol char(100),
@old_datecol datetime
AS
DELETE two_way_test2 WHERE pkcol = @old_pkcol
GO
©1988-2001 Microsoft Corporation. All Rights Reserved.
Step 6: Test the Application
New Information - September 2001.
To test the application you have built, execute updates and then select the data to see the results. Use the datecol column to see when rows were updated at each database, relative to each other.
Examples
1. Execute updates to the first row in test1 and test2
USE test1
GO
UPDATE two_way_test1 SET intcol = 20 , charcol = 'updated at test1' WHERE pkcol = 1
USE test2
GO
UPDATE two_way_test2 SET intcol = 60 , charcol = 'updated at test2' WHERE pkcol = 1
2. Select data from both tables to verify that the changes were propagated
SELECT * FROM test1..two_way_test1 WHERE pkcol = 1
SELECT * FROM test2..two_way_test2 WHERE pkcol = 1
If the starting value of intcol was 10, the value in test1 was incremented by 10 and the value in test2 was incremented by 50. The conflict resolution in the update custom procedure sums the values in this column, so this integer value converges to 70 in both databases. It may take a few seconds to see the results in both tables.
©1988-2001 Microsoft Corporation. All Rights Reserved.
Duplicación con SQL Server 2000 Windows CE
¿Mediante Microsoft® SQL Server? 2000 y la duplicación de mezcla, puede publicar datos en dispositivos móviles que ejecutan SQL Server 2000 Windows CE (SQL Server CE). La duplicación de mezcla está adaptada a la duplicación con Suscriptores móviles desconectados, ya que permite realizar actualizaciones en el Suscriptor mientras está desconectado de la red y del Publicador. Posteriormente, cuando se vuelva a conectar el dispositivo, se pueden mezclar los cambios realizados en el Suscriptor con otros cambios realizados en el Publicador y otros Suscriptores.
La duplicación con SQL Server CE es posible con publicaciones de mezcla mediante suscripciones anónimas. La administración de suscripciones se dirige al Suscriptor y la información acerca del Suscriptor que ejecuta SQL Server CE y la suscripción no se almacena en el Publicador.
Cómo funciona la duplicación de SQL Server CE
La publicación a Suscriptores que ejecutan SQL Server CE es similar a la publicación en otros tipos de Suscriptores que utilizan suscripciones anónimas.
Cree una publicación de mezcla y, en la página Especificar tipos de Suscriptor del Asistente para creación de publicaciones, seleccione Dispositivos con SQL Server CE como el tipo de Suscriptor que se puede suscribir a esta publicación. Si selecciona esta opción, se habilitarán automáticamente las suscripciones anónimas para la publicación.
Una aplicación SQL Server CE puede suscribirse a la publicación mediante el Objeto de duplicación de SQL Server CE. Cuando se crea la suscripción, se aplica la instantánea inicial para crear la base de datos de suscripciones en el dispositivo que ejecuta SQL Server CE.
Los usuarios pueden modificar datos en la base de datos de suscripciones con o sin conexión. Cuando se vuelven a conectar, las modificaciones de datos realizadas en el Suscriptor se envían al Publicador y se mezclan con los cambios realizados en el Publicador y en otros Suscriptores. Los cambios realizados en el Publicador o los propagados al Publicador desde la última sincronización se envían al Suscriptor.
El Objeto de duplicación de SQL Server CE, dentro de SQL Server CE, controla la ejecución del Agente de mezcla de SQL Server para completar la sincronización. Si se producen errores provocados por cambios en los mismos datos, los conflictos se solucionarán mediante las resoluciones de conflictos que ha elegido al crear la publicación.
Para obtener más información, vea la documentación de SQL Server CE.
Véase también
Suscripciones anónimas
Duplicación de mezcla
©1988-2001 Microsoft Corporation. Reservados todos los derechos.
Duplicación
Suscripciones anónimas
Nueva información: septiembre de 2001.
Todas las reglas de las suscripciones de extracción son aplicables a las suscripciones anónimas. Una suscripción anónima es un tipo de suscripción de extracción para la que no se almacena información detallada acerca de la suscripción ni del suscriptor. Se inicia en el suscriptor, y éste es responsable de mantener sincronizada la suscripción anónima.
Utilice las suscripciones anónimas cuando:
Las aplicaciones disponen de un gran número de suscriptores.
No desea la sobrecarga de mantener información adicional en el publicador o distribuidor.
Los suscriptores utilizan Internet para tener acceso a las publicaciones.
Un factor decisivo en la utilización de suscripciones anónimas con las duplicaciones transaccional y de instantáneas es la limpieza de la base de datos de distribución. El Agente de limpieza de distribución, que se ejecuta por programación de manera predeterminada cada 10 minutos, limpia la base de datos de distribución. EL Agente de limpieza de distribución quita las transacciones duplicadas de la base de datos de distribución; sin embargo, si utiliza suscripciones anónimas, las transacciones se guardan durante el período de retención de la suscripción, para proporcionar a las suscripciones anónimas tiempo para sincronizarse.
Con la mezcla, el factor importante que afecta a la escala es si los suscriptores conocen o no a otros suscriptores. Los metadatos de todas las suscripciones globales se almacenan en la tabla de sistema Sysmergesubscriptions. Se puede ver información acerca de todos los suscriptores, el publicador y todas las suscripciones globales a publicaciones a las que estén suscritos.
Si habilita las suscripciones anónimas en la publicación, el usuario que crea la suscripción de extracción puede especificar en el Asistente para crear suscripciones de extracción que la suscripción sea anónima, por medio del Administrador de sincronización de Windows o en el procedimiento almacenado.
Para crear una suscripción de extracción o anónima
Administrador corporativo
Cómo crear una suscripción de extracción o anónima (Administrador corporativo)
Para crear una suscripción de extracción o anónima
En el suscriptor, abra el Administrador corporativo de SQL Server, expanda un grupo de servidores, expanda la carpeta Duplicación, haga clic con el botón secundario del mouse (ratón) en la carpeta Suscripciones y, a continuación, haga clic en Nueva suscripción de extracción.
Siga los pasos del Asistente para suscripciones de extracción.
Si la publicación permite suscripciones anónimas, el Asistente para suscripciones de extracción mostrará la página Permitir suscripción anónima, donde puede definir la nueva suscripción como anónima.
Windows
Cómo crear una suscripción anónima (Administrador de sincronización de Windows)
En el menú Inicio, seleccione Programas, Accesorios y, a continuación, haga clic en Sincronizar.
Haga clic en Para crear una suscripción: seleccione ésta y haga clic en Propiedades, haga clic en Propiedades y, a continuación, seleccione Especificando la información de publicación y suscripción manualmente.
Escriba el nombre de la suscripción, del suscriptor, de la base de datos de suscripciones, del publicador, de la base de datos de publicaciones y del distribuidor, y el tipo de publicación.
Transact-SQL
Cómo crear una suscripción anónima (Transact-SQL)
Para agregar una suscripción anónima a una publicación de instantáneas (Transact-SQL)
Ejecute sp_addpublication con allow_pull, allow_anonymous e immediate_sync establecidos como TRUE para habilitar las suscripciones anónimas.
Ejecute sp_addpullsubscription para crear la suscripción anónima en el suscriptor.
Ejecute sp_addpullsubscription_agent para crear un trabajo programado para el agente de distribución en el suscriptor.
Para agregar una suscripción anónima (transaccional)
Ejecute sp_addpublication con allow_pull, allow_anonymous e immediate_sync establecidos como TRUE para habilitar las suscripciones anónimas.
Ejecute sp_addpullsubscription para crear la suscripción anónima en el suscriptor.
Ejecute sp_addpullsubscription_agent para crear un trabajo programado para el agente de distribución en el suscriptor.
Para agregar una suscripción anónima a una publicación de mezcla
Ejecute sp_addmergepublication con allow_pull y allow_anonymous establecidas como TRUE para habilitar las suscripciones anónimas en el publicador.
Ejecute sp_addmergepullsubscription para crear la suscripción anónima en el suscriptor.
Ejecute sp_addmergepullsubscription_agent para crear un trabajo programado para el agente de mezcla en el suscriptor.
SQL-DMO
SQL-DMO
Para ver o modificar suscripciones de extracción o anónimas
Administrador corporativo
Cómo ver o modificar las suscripciones de extracción o anónimas (Administrador corporativo)
En el suscriptor, en el Administrador corporativo de SQL Server, expanda un grupo de servidores y la carpeta Duplicación, haga clic en la carpeta Suscripciones, haga clic con el botón secundario del mouse (ratón) en la suscripción que desea modificar, en el panel derecho del Administrador corporativo de SQL Server y, a continuación, haga clic en Propiedades.
Transact-SQL
Cómo ver o modificar suscripciones de extracción o anónimas (Transact-SQL)
Para ver las propiedades de una suscripción de extracción o anónima de una publicación de instantáneas
Ejecute sp_helpsubscription para enumerar la información de suscripción asociada a una publicación, un artículo, un suscriptor o un conjunto de suscripciones en particular.
Ejecute sp_helppullsubscription para mostrar información acerca de una o más suscripciones en el suscriptor.
Ejecute sp_helpsubscriberinfo para mostrar información acerca del suscriptor.
Para modificar las propiedades de una suscripción de extracción o anónima de una publicación de instantáneas
Ejecute sp_changesubscriber para cambiar las opciones del suscriptor.
Ejecute sp_changesubstatus para cambiar el estado del suscriptor.
Para ver las propiedades de una suscripción de extracción y anónima (transaccional)
Ejecute sp_helpsubscription para enumerar la información de suscripción asociada a una publicación, un artículo, un suscriptor o un conjunto de suscripciones en particular.
Ejecute sp_helppullsubscription para mostrar información acerca de una o más suscripciones en el suscriptor.
Ejecute sp_helpsubscriberinfo para mostrar información acerca del suscriptor.
Para modificar las propiedades de una suscripción de extracción y anónima (transaccional)
Ejecute sp_changesubscriber para cambiar las opciones del suscriptor.
Ejecute sp_changesubstatus para cambiar el estado del suscriptor.
Para ver las propiedades de una suscripción de extracción y anónima (mezcla)
Ejecute sp_helpmergepullsubscription para mostrar una lista de la información de suscripción asociada a una publicación particular, un artículo, un suscriptor o un conjunto de suscripciones.
Para modificar las propiedades de una suscripción de extracción y anónima (mezcla)
Ejecute sp_changemergepullsubscription para cambiar las opciones del suscriptor.
SQL-DMO
SQL-DMO
Para eliminar una suscripción anónima
Transact-SQL
Cómo eliminar una suscripción anónima (Transact-SQL)
Nueva información: septiembre de 2001.
Para deshabilitar las publicaciones de instantáneas que permiten suscripciones anónimas
Ejecute sp_droparticle n veces para eliminar cada uno de los artículos de la publicación.
Ejecute sp_droppublication para eliminar la publicación.
Ejecute sp_replicationdboption para deshabilitar la duplicación de la base de datos actual.
Nota El publicador no conoce las suscripciones anónimas. Los pasos anteriores deshabilitan todas las suscripciones anónimas de una publicación al quitar dicha publicación.
Para deshabilitar las publicaciones transaccionales que permiten suscripciones anónimas
Ejecute sp_droparticle n veces para eliminar cada uno de los artículos de la publicación.
Ejecute sp_droppublication para eliminar la publicación.
Ejecute sp_replicationdboption para deshabilitar la duplicación de la base de datos actual.
Nota El publicador no conoce las suscripciones anónimas. Los pasos anteriores deshabilitan todas las suscripciones anónimas de una publicación al quitar dicha publicación.
Para deshabilitar las publicaciones de mezcla que permiten suscripciones anónimas
Ejecute sp_dropmergearticle n veces para eliminar cada artículo de la publicación.
Ejecute sp_dropmergepublication para eliminar la publicación.
Ejecute sp_mergesubscription_cleanup para quitar los metadatos de la configuración de mezcla de todos los artículos de mezcla de la base de suscripción.
Ejecute sp_replicationdboption para deshabilitar la duplicación de la base de datos actual.
Nota El publicador no conoce las suscripciones anónimas. Los pasos anteriores deshabilitan todas las suscripciones anónimas de una publicación al quitar dicha publicación.
SQL-DMO
SQL-DMO
©1988-2001 Microsoft Corporation. Reservados todos los derechos.
Duplicación de mezcla
Nueva información: septiembre de 2001.
La duplicación de mezcla es el proceso de distribuir datos desde el publicador a los suscriptores, permitiendo que hagan actualizaciones mientras están conectados o desconectados y posteriormente mezclando las actualizaciones entre sitios cuando están conectados.
La duplicación de mezcla permite que los diferentes sitios funcionen de forma autónoma y más tarde mezclen las actualizaciones en un solo resultado uniforme. La instantánea inicial se aplica a los suscriptores; ¿A continuación Microsoft® SQL Server? 2000 hace un seguimiento de los cambios realizados en los datos publicados en el publicador y en los suscriptores. Los datos se sincronizan continuamente entre los servidores, a una hora programada o bajo petición. Puesto que las actualizaciones tienen lugar en más de un servidor, los mismos datos pueden haber sido actualizados por el publicador o por más de un suscriptor. Por lo tanto, pueden producirse conflictos al mezclar las actualizaciones.
La duplicación de mezcla incluye opciones predeterminadas y opciones personalizadas para la resolución de conflictos, que pueden definirse al configurar las publicaciones de mezcla. Cuando se produce un conflicto, el Agente de mezcla invoca una resolución y determina qué datos se aceptarán y se propagarán a otros sitios.
La duplicación de mezcla es útil cuando:
Varios suscriptores necesitan actualizar datos en diferentes ocasiones y propagar los cambios al publicador y a otros suscriptores.
Los suscriptores necesitan recibir datos, realizar cambios sin conexión y sincronizar más adelante los cambios con el Publicador y otros suscriptores.
No espera que se produzcan muchos conflictos cuando se actualicen los datos en los diferentes sitios (debido a que los datos se filtran en particiones y a continuación se publican en diferentes suscriptores o debido a los usos de la aplicación). No obstante, si se producen conflictos resulta aceptable infringir las propiedades ACID.
Tanto la actualización en cola como la duplicación de mezcla permiten la actualización en el publicador y en los suscriptores mientras no están conectados; sin embargo, hay diferencias significativas entre los dos métodos. Para obtener más información, consulte Duplicación de mezcla o suscripciones actualizables.
©1988-2001 Microsoft Corporation. Reservados todos los derechos.
Las últimas secciones, creo que serían las más interesantes.