Creación de usuario y contraseña en excel con visual basic
Necesito un mega favor.
Lo que pasa es que quiero un macro donde al introducir su nombre de usuario y contraseña les de acceso al libro de excel.
Me gustaría que éstas contraseñas estuvieran en una hoja de excel y saber cuando entro uno de ellos.
Es que lo intento y me sale error. Ayuda!
1 respuesta
H o l a:
Envíame tu archivo con tu formulario o con lo que tengas para capturar el usuario y la contraseña. Lo reviso y actualizo el código y el libro.
Mi correo [email protected]
En el asunto del correo escribe tu nombre de usuario “Valeria Trujillo” y el título de esta pregunta.
H o l a:
Te anexo la macro validar el usuario y contraseña; y también para registrar cada acceso al sistema:
Private Sub CommandButton1_Click()
'Por.Dante Amor
Set h1 = Sheets("BD_USUARIOS")
Set h3 = Sheets("BD_ACCESOS")
If Txt_Nombre = "" Then
MsgBox "Captura el Usuario"
Txt_Nombre.SetFocus
Exit Sub
End If
'
If Txt_Contraseña = "" Then
MsgBox "Captura la contraseña"
Txt_Contraseña.SetFocus
Exit Sub
End If
'
Set b = h1.Columns("A").Find(Txt_Nombre, LookAt:=xlWhole, MatchCase:=True)
If Not b Is Nothing Then
If h1.Cells(b.Row, "B") <> Txt_Contraseña Then
MsgBox "Lo siento. No puede acceder. Contraseña incorrecta", vbCritical, "SGC"
Txt_Nombre.SetFocus
Exit Sub
End If
Else
MsgBox "Lo siento. No puede acceder. Usuario no existe", vbCritical, "SGC"
Txt_Nombre.SetFocus
Exit Sub
End If
'
u = h3.Range("A" & Rows.Count).End(xlUp).Row + 1
h3.Cells(u, "A") = Txt_Nombre
h3.Cells(u, "B") = Date
h3.Cells(u, "C") = Time
hojas = Array("BD_USUARIOS", "BD_PERFILES", "BD_ACCESOS")
For Each h In Sheets
existe = False
For i = LBound(hojas) To UBound(hojas)
If h.Name = hojas(i) Then
existe = True
Exit For
End If
Next
If existe = False Then
h.Visible = -1
End If
Next
Unload Me
MsgBox "BIENVENIDO", vbInformation, "SGC"
End SubLos accesos se registran en la hoja "BD_ACCESOS".
Las hojas de control "BD_USUARIOS", "BD_ACCESOS" y "BD_PERFILES", permanecerán ocultas.
Las hojas de la aplicación "Inicio" y "Hoja1", y las que desees se mostrarán una vez que el usuario haya entrado con un usuario y contraseña correcta.
