Enviar Rango de hoja en cuerpo de mail vía Lotus Notes

Te puedo ayudar. Pero no es mejor que adjuntes un archivo, en vez de copiar en el body todo ese rango.

es un ejemplo del rango. en si el rango es mas corto pero necesito hacer eso, es por eso la pregunta por que el archivo ya lo adjunta con esta macro, saludos y gracias

Pero supongo que quieres que se vea como una imagen, con el formato de las celdas, no como texto plano

si exacto seria lo ideal como imagen

Hace un tiempo, lo intente, y no pude embeber dentro del correo una imagen, pero mañana cuando este en mi trabajo, y tenga Lotus, te ayudo con gusto, investigando.

Es una pregunta recurrente en los foros de programación, pero nunca he encontrado una respuesta definitiva.

Aunque acabo de encontrár esto http://www.mrexcel.com/forum/excel-questions/518746-send-range-rich-text-body-through-lotus-notes.html que parece funcionar, en teoría insertan en formato html en el body del correo, y obviamente el html soporta el formato de las celdas. Para esto crean un documento de word temporal y de ahi lo pasan al lotus. Si puedes pruébalo, yo mañana lo probare a ver como nos va.

Sub Notes_Email_Excel_Cells2()
Dim NSession As Object
Dim NDatabase As Object
Dim NUIWorkSpace As Object
Dim NDoc As Object
Dim NUIdoc As Object
Dim WordApp As Object
Dim subject As String
subject = "Pasted Excel cells using Word PasteSpecial method " & Now
Debug.Print subject
Set NSession = CreateObject("Notes.NotesSession")
Set NUIWorkSpace = CreateObject("Notes.NotesUIWorkspace")
Set NDatabase = NSession.GetDatabase("", "")
If Not NDatabase.IsOpen Then NDatabase.OPENMAIL
'Create a new Lotus Notes document
Set NDoc = NDatabase.CreateDocument
With NDoc
.SendTo = "[email protected]" 'CHANGE RECIPIENT EMAIL ADDRESS
.CopyTo = ""
.subject = subject
'Email body text, including marker text which will be replaced by the Excel cells
.body = "Text in email body" & vbLf & vbLf & _
"**PASTE EXCEL CELLS HERE**" & vbLf & vbLf & _
"Excel cells are shown above"
.Sabe True, False
End With
'Edit the just-created document to copy and paste the Excel cells into it via Word
Set NUIdoc = NUIWorkSpace.EDITDocument(True, NDoc)
With NUIdoc
'Find the marker text in the Body item
.GotoField ("Body")
.FINDSTRING "**PASTE EXCEL CELLS HERE**"
'.DESELECTALL 'Uncomment to leave the marker text in place (cells are inserted immediately before)
'Copy Excel cells to clipboard
Sheets("Sheet1").Range("A1:E6").Copy 'CHANGE SHEET AND RANGE TO BE COPIED AND PASTED
'Create a temporary Word Document
Set WordApp = CreateObject("Word.Application")
WordApp.Visible = False 'True to aid debugging
WordApp.Documents.Add
'Paste into Word document and copy to clipboard
With WordApp.Selection
.PasteSpecial DataType:=10 'Enum WdPasteDataType: 10 = HTML; 2 = Text; 1 = RTF
.WholeStory
.Copy
End With
'Paste from clipboard (Word) to Lotus Notes document
.Paste
Application.CutCopyMode = False
WordApp.Quit SaveChanges:=False
Set WordApp = Nothing
.Send
.Close
End With
Set NSession = Nothing
End Sub

Dale lo pruebo y te comento, muchas gracias :)

Lo probe y no me funciona me tira error de Automatizacion? y cambie una linea

.Sabe True, False por .Save True, False me avisas como te fue saludos.

aquí esta la solución, con este me funciono sin problemas, pero mi duda es como copiar una imagen no por que no me la toma,

Sub Notes_Email_Excel_Cells3()
Dim NSession As Object
Dim NDatabase As Object
Dim NUIWorkSpace As Object
Dim NDoc As Object
Dim NUIdoc As Object
Dim WordApp As Object
Dim subject As String
subject = "Envío Formulario " & Now
Debug.Print subject
Set NSession = CreateObject("Notes.NotesSession")
Set NUIWorkSpace = CreateObject("Notes.NotesUIWorkspace")
Set NDatabase = NSession.GetDatabase("", "")
If Not NDatabase.IsOpen Then NDatabase.OPENMAIL
'Create a new Lotus Notes document
Set NDoc = NDatabase.CreateDocument
With NDoc
.SendTo = "" 'CHANGE RECIPIENT EMAIL ADDRESS
.CopyTo = ""
.subject = subject
'Email body text, including marker text which will be replaced by the Excel cells
.body = "Favor cursar,." & vbLf & vbLf & _
"****" & vbLf & vbLf & _
"Envío de info"
.Sabe True, False
End With
'Edit the just-created document to copy and paste the Excel cells into it via Word
Set NUIdoc = NUIWorkSpace.EDITDocument(True, NDoc)
With NUIdoc
'Find the marker text in the Body item
.GotoField ("Body")
.FINDSTRING "****"
'.DESELECTALL 'Uncomment to leave the marker text in place (cells are inserted immediately before)
'Copy Excel cells to clipboard
Sheets("Hoja1").Range("A1:H25").Copy 'CHANGE SHEET AND RANGE TO BE COPIED AND PASTED
'Create a temporary Word Document
Set WordApp = CreateObject("Word.Application")
WordApp.Visible = False 'True to aid debugging
WordApp.Documents.Add
With WordApp.Selection
.PasteSpecial DataType:=10 'Enum WdPasteDataType: 10 = HTML; 2 = Text; 1 = RTF
.WholeStory
.Copy
End With
Application.CutCopyMode = False
WordApp.Quit SaveChanges:=False
Set WordApp = Nothing
.Paste
.Send
.Close
End With
Set NSession = Nothing
End Sub

Saludos

Si!, funciona perfecto, solo cambiar el "sabe" por el "save". Pero no entendí tu pregunta.. ¿quieres adjuntar ahora una imagen?

lo que pasa que en el rango hay una imagen, existe forma que la copie? por que cuando la agrego me tira error de Word. Saludos