Transponer datos excel

Suponiendo que los datos estuvieran en una hoja llamada Datos, en el rango A1:G100, prueba pegando la siguiente fórmula en el rango A2:D2 de otra hoja (la fila 1 de dicha hoja se supone que sería la de títulos):
=INDICE(Datos!$A$1:$G$100;SI(COLUMNA()<>3;ENTERO((FILA()-2)/5)+2;1);SI(COLUMNA()<3;COLUMNA();RESIDUO(FILA()+3;5)+3))
Luego copia y pega la fórmula hacia abajo hasta que comiencen a aparecer ceros (lo que significará que ya no hay más datos que transponer)

Excelente respuesta, me ayudo bastante. Sin embargo lo que no entiendo porque ha variado el orden (de arriba para abajo) al incrementar más columnas a la hoja de datos claro que si coge la cabecera y su dato de la fila correctamente. ¿Me podría aclarar como hago para que también el orden en forma vertical se mantenga? Muchas gracias de antemano por la respuesta.

La fórmula estaba diseñada suponiendo que el rango de datos tenía 7 columnas, y si en realidad tiene más (o, para el caso, menos), no funcionará bien.
Para 8 columnas la fórmula sería:
=INDICE(Datos!$A$1:$H$100;SI(COLUMNA()<>3;ENTERO((FILA()-2)/6)+2;1);SI(COLUMNA()<3;COLUMNA();RESIDUO(FILA()-2;6)+3))
Sin saber exactamente el número de columnas del rango de datos no puedo ser más concreto. Es casi seguro que se podría escribir una fórmula que se amoldara al número de columnas, sea este el que fuera, pero habría que complicarla mucho y no creo que merezca la pena.

Gracias por el tiempo que demanda tu atención a mi consulta, pero creo valdría el esfuerzo si me ayudas con proporcionarme la fórmula de tal manera que me permita adaptar la fórmula al numero de columnas porque el sistema del que extraemos la hoja de datos cambia el numero de columnas de un reporte a otro y que básicamente se basa siempre a las dos primeras columnas (es decir código+documento) y que las demás columnas o se reducen i en otras se incrementan en su numero.
Y disculpa la molestia de complicarlo la fórmula. (Espero haber sido explicito en mi consulta)
Gracias

Pues lo siento pero no tengo tiempo para la fórmula, acabo antes escribiendo código para VBA:
Sub Transponer()
    Dim wksDatos As Worksheet, wksTrans As Worksheet
    Dim rngDatos As Range
    Dim lngFilaDatos As Long, lngFilaTrans As Long, intColumna As Integer
    Set wksDatos = ThisWorkbook.Worksheets("Datos")
    Set wksTrans = ThisWorkbook.Worksheets.Add
    wksTrans.Name = "Transposición"
    Set rngDatos = wksDatos.[A1].CurrentRegion
    lngFilaDatos = 2
    lngFilaTrans = 2
    Application.ScreenUpdating = False
    While rngDatos.Cells(lngFilaDatos, 1) <> ""
        For intColumna = 3 To rngDatos.Columns.Count
            With wksTrans
                .Cells(lngFilaTrans, 1).Value = rngDatos.Cells(lngFilaDatos, 1).Value
                .Cells(lngFilaTrans, 2).Value = rngDatos.Cells(lngFilaDatos, 2).Value
                .Cells(lngFilaTrans, 3).Value = rngDatos.Cells(1, intColumna).Value
                .Cells(lngFilaTrans, 4).Value = rngDatos.Cells(lngFilaDatos, intColumna).Value
                lngFilaTrans = lngFilaTrans + 1
            End With
        Next intColumna
        lngFilaDatos = lngFilaDatos + 1
    Wend
    Application.ScreenUpdating = True
    Set rngDatos = Nothing
    Set wksTrans = Nothing
    Set wksDatos = Nothing
End Sub
Tienen cuenta que:
- La hoja con los datos a transponer tiene que llamarse Datos
- Los datos tienen que comenzar en la celda A1 de la hoja Datos.
- El código tiene que estar en el mismo libro que dicha hoja
- Los datos serán transpuestos en una hoja nueva (en el mismo libro que la hoja Datos) que se llamará Transposición.