Scroll de texto automático

Bedelludrica como estas.
Soy nuevo en este sitio, y esta es mi primera pregunta, que te la hago a ti porque en una de las respuestas que vi que le diste a otra persona, resolviste otra duda mía.
Resulta que se hacer scroll normal, es decir que al hacer un clic en el mouse sobre la flecha, el texto baja o sube alguna cantidad de líneas.
Lo que quisiera saber, es como hacer para que este texto suba o baje solo con posicionar el mouse sobre la flecha y que por supuesta al retirarlo, el texto pare.
Me seria de gran ayuda tu respuesta.
1

1 Respuesta

252.550 pts.
Ahora no puedo darte nada . Debes esperar un par de días (no estoy en casa). Si quieres deja esta pregunta activa.
Perdoname, por el retraso pero me había olvidado de ti, la próxima vez si ves que tardo más de dos días en contestar avisame en [email protected]
Bien aquí te pongo tres comportamientos:( Funcionan poerfectamente y te serán muy útiles, si no lo sabes usar bien me puedes hacer otra pregunta para aprender a usarlos)
-1º- Este comportamiento es para cuando quieras incluir botones de subir y bajar texto y nada más (es decir sin barra de texto).
-2º-Este coportamiento es para los botones de subir y bajar texto que tengan una barra de texto (para usar este comportamiento también debes usar el tercero).
3º-Este comportamiento es para usar conjuntamennte con el 2º y se lo debes vincular al topo de la barra de texto)
----------------------------------------------

--Creado por bedelludrica
property p_velocidad, p_texto,p_rutina
on getBehaviorTooltip me
return \
"Este comportamiento debes vincularlo al topo " & \
"e indicar en que sprite se encuentra la barra de desplazamiento de texto " & \
"NOTA:da igual donde coloques el topo pues se colocara en la posición" &\
"de volumen 0 al comenzar la película"
end getBehaviorTooltip
on getPropertyDescriptionList me
lista=[:]
addprop lista, #p_texto,[#comment:"¿elige el texto ?",\
#format:#member,#default:""]
addProp lista, #p_rutina, [#comment: "elige la rutina" ,#format:#String\
,#range:["On MouseDown","On MouseEnter"]\
,#default:"On MouseDown"]
addprop lista, #p_velocidad,[#comment:"¿Cual es la velocidad para subir o bajar texto?",\
#format:#integer,#default:2, #range:[#min:-6,#max:6]]
return lista
end getPropertyDescriptionList
on exitframe me
if p_rutina = "On MouseDown" then
if rollover(me.spritenum) then
if the mousedown then
scrollByLine member p_texto, p_velocidad
end if
end if
else if p_rutina = "On MouseEnter" then
if rollover(me.spritenum) then
scrollByLine member p_texto, p_velocidad
end if
end if
end
----------------------------------------------

--creado por bedelludrica
property p_velocidad, p_barra,p_rutina
on getBehaviorTooltip me
return \
"Este comportamiento debes vincularlo al topo " & \
"e indicar en que sprite se encuentra la barra de desplazamiento de texto " & \
"NOTA:da igual donde coloques el topo pues se colocara en la posición" &\
"de volumen 0 al comenzar la película"
end getBehaviorTooltip
on getPropertyDescriptionList me
lista=[:]
addprop lista, #p_barra,[#comment:"¿que sprite es la barra del topo?",\
#format:#integer,#default:1]
addProp lista, #p_rutina, [#comment: "elige la rutina" ,#format:#String\
,#range:["On MouseDown","On MouseEnter"]\
,#default:"On MouseDown"]
addprop lista, #p_velocidad,[#comment:"¿Cual es la velocidad para subir o bajar texto?",\
#format:#integer,#default:2, #range:[#min:-6,#max:6]]
return lista
end getPropertyDescriptionList
on exitframe me
if p_rutina = "On MouseDown" then
if rollover(me.spritenum) then
if the mousedown then
sprite(p_barra).locv= sprite(p_barra).locv+p_velocidad
end if
end if
else if p_rutina = "On MouseEnter" then
if rollover(me.spritenum) then
sprite(p_barra).locv= sprite(p_barra).locv+p_velocidad
end if
end if
end
----------------------------------------------

--creado por bedelludrica
property p_barra,p_maximo_o_minimo, volumen,altura, linea_f
on getBehaviorTooltip me
return \
"Este comportamiento debes vincularlo al topo " & \
"e indicar en que sprite se encuentra la barra de desplazamiento de texto " & \
"NOTA:da igual donde coloques el topo pues se colocara en la posición" &\
"de volumen 0 al comenzar la película"
end getBehaviorTooltip
on getPropertyDescriptionList me
list=[:]
addprop list, #p_barra,[#comment:"¿que sprite es la barra del topo?",\
#format:#integer,#default:2]
return list
end getPropertyDescriptionList
on enterframe me
sprite(me.spritenum).loch=sprite(p_barra).loch
sprite(me.spritenum).loch=sprite(p_barra).loch
end
on beginsprite me
sprite (me.spritenum).moveableSprite =true
altura=sprite(p_barra).height
localizacion=sprite(p_barra).locv
linea_f=0
sprite(me.spritenum).locv=localizacion
sprite(me.spritenum).loch=sprite(p_barra).loch
updatestage
end
on exitframe me
volumen_max= member("texto").height+10- member("texto").pageheight
sprite(me.spritenum).constraint= p_barra
altura=sprite(p_barra).height
topo_inicio=sprite(p_barra).locv
topo_actual=sprite(me.spritenum).locv
topo_relativo=topo_actual-topo_inicio
volumen=(topo_relativo*volumen_max)/altura
member("texto").scrolltop=volumen
end
Hola bedelludrica, gracias por responderme: en realidad no había podido entrar desde hacia un tiempo.
No entiendo a que te refieres con la palabra topo, de pronto yo la conozco de alguna otra forma, no soy muy experto en programación como tal, si pudieras explicarme un poco más como debo aplicar estos comportamientos te lo agradecería.
Gracias por tu tiempo.
El topo. En las barras para desplazar el texto hay una barra vertical y un botón que se desplaza a lo largo de esa barra para subir y bajar el texto. Pues bien ese botón que pulsas y lo desplazas es el topo.
Como se usan los comportamientos:
-Primero debes copiar cada comportamiento en cada ventana de script de director.
-Ahora debes pulsar sobre la "i" de color azul de que hay en la ventana de script.
-Se te habrá abierto otra ventana
-En esa ventana la opción movie la debes cambiar a behaviour
-Ahora ya tienes comportamientos.
-Los debes compilas pulsando sobre el botón con forma de rayo que hay en la ventana de script.
- Ahora ya esta.
-Para usarlos solo debes abrir la ventana de cast.
-Hay tendrás todos los comportamientos
-Para usarlos solo tienes que arrastrarlos sobres los objetos del escenario
Comportamiento 1º
Este comportamiento lo debes arrastras sobre un miembro, por ejemplo un dibujo.
Cuando lo hayas arrastrado se te habrá abierto otra ventana, que te pregunta donde esta el texto, que quieres que suba o baje el texto, velocidad del movimiento...
Debes vincular este comportamiento a dos miembros uno para el botón de bajar y otro para el botón de subir.
Comportamiento 2º
Es igual que el primero pero para usar este debes usarlo con el comportamiento nº 3
Comportamiento 3º
Este comportamiento debes usarlo con el nº 2 para crear una barra de texto
Debes vincularlo sobre el topo de texto. Te aparecerá una ventana en la que debes decir donde se encuentra la barra de texto.
La barra de texto debes ser un elemento vertical y de anchura 1 bit
Debes tener en el stage el topo y la barra. Con mi comportamiento al iniciar la película el topo se coloca automáticamente en la parte superior de la barra y listo para funcionar.
Prueba lo que te he dicho si tienes problemas inicia otra pregunta distinta.

Añade tu respuesta

Haz clic para o

Más respuestas relacionadas